keycloak.plugins.apple-identity-provider-keycloak: init at 1.17.0

Signed-off-by: Anish Pallati <i@anish.land>

pkgs/by-name/ke/keycloak/all-plugins.nix

@@ -5,6 +5,7 @@
   junixsocket-native-common,
 }:
 {
+  apple-identity-provider-keycloak = callPackage ./apple-identity-provider-keycloak { };
   keycloak-2fa-sms-authenticator = callPackage ./keycloak-2fa-sms-authenticator { };
   keycloak-discord = callPackage ./keycloak-discord { };
   keycloak-enforce-mfa-authenticator = callPackage ./keycloak-enforce-mfa-authenticator { };

pkgs/by-name/ke/keycloak/apple-identity-provider-keycloak/default.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  gradle_8,
+  nix-update-script,
+}:
+let
+  gradle = gradle_8;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "apple-identity-provider-keycloak";
+  version = "1.17.0";
+
+  src = fetchFromGitHub {
+    owner = "klausbetz";
+    repo = "apple-identity-provider-keycloak";
+    tag = finalAttrs.version;
+    hash = "sha256-0/uHQwgyHwy+5ynRHs0ot0iIBVUckEs65YxkWLQNgbY=";
+  };
+
+  nativeBuildInputs = [ gradle ];
+
+  mitmCache = gradle.fetchDeps {
+    pkg = finalAttrs.finalPackage;
+    data = ./deps.json;
+  };
+
+  __darwinAllowLocalNetworking = true;
+
+  strictDeps = true;
+  __structuredAttrs = true;
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm444 -t "$out" build/libs/apple-identity-provider-${finalAttrs.version}.jar
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://github.com/klausbetz/apple-identity-provider-keycloak";
+    changelog = "https://github.com/klausbetz/apple-identity-provider-keycloak/releases/tag/${finalAttrs.version}";
+    description = "Keycloak identity provider extension for Sign in with Apple";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ anish ];
+    sourceProvenance = with lib.sourceTypes; [
+      fromSource
+      binaryBytecode # mitm cache
+    ];
+    platforms = lib.platforms.unix;
+  };
+})