compiler-rt: enable build of libatomic

LLVM stdenvs lack a set of `__atomic_*` routines that compilers
sometimes rely on, making it impossible to build certain C programs in
them. The reason we lack these routines is that we're using neither
compiler-rt's implementation of them (which was disabled by default a
long time ago) nor gcc's implementation (libatomic). See #391740 for a
more detailed explanation and an example of program that cannot be built.

Since no particular preference was expressed as to which approach
should be used to solve this, I'm going with LLVM's implementation
and recommended setup, which seems to be used also in AIX, Fuchsia
and Apple platforms. This consists of enabling a CMake flag,
`COMPILER_RT_BUILD_STANDALONE_LIBATOMIC`, which causes the routines to
be built and shipped in a separate DSO (placing them in a DSO instead
of `builtins.a` is needed for correctness, as it ensures the lock
section is unique in memory).

As with the other builtins, I'm symlinking this DSO to `libatomic.so` so
that downstream packages don't need specific/complicated logic for LLVM.

Other details:
- For static platforms, since no dynamic linking is expected at all, it
  should be correct to ship the symbols in `builtins.a`.
  So, that's what I'm doing in those cases.
- Since v19, compiler-rt allows using pthread locks rather than ad-hoc
  ones for the atomic routines. Since this plays better with
  instrumentation, I'm enabling this whenever libc is available.
- It would be nice to put the DSO in a separate output / derivation, so
  that the rest of compiler-rt isn't pulled into the runtime closure,
  but it isn't high prio since compiler-rt doesn't pull in dependencies
  other than libc, libc++ and unwinder.

Fixes: https://github.com/NixOS/nixpkgs/issues/311930

pkgs/development/compilers/llvm/common/compiler-rt/default.nix

@@ -21,6 +21,23 @@
   # are, so long as it provides some builtins.
   doFakeLibgcc ? stdenv.hostPlatform.isFreeBSD,
 
+  # Whether to build the set of __atomic_* routines that would typically
+  # be provided by libatomic in gcc environments.
+  withAtomics ?
+    stdenv.hostPlatform.useLLVM
+    && ((stdenv.cc.libc != null) || !stdenv.hostPlatform.hasSharedLibraries),
+  # If withAtomics is enabled, setting this to true ships those routines
+  # in a separate DSO (aliased as libatomic to match gcc's) rather than
+  # making them part of builtins.a. Unless no dynamic linking is used at
+  # all, this is the correct setup as it ensures the locks are unique in
+  # memory.
+  withAtomicsLib ? stdenv.hostPlatform.hasSharedLibraries,
+  # If withAtomics is enabled, this selects the pthreads-based
+  # implementation of the routines instead of the implementation
+  # using ad-hoc mutexes (which doesn't depend on libc at all).
+  # Use of pthreads helps code play better with sanitizers.
+  withAtomicsPthread ? lib.versionAtLeast release_version "19" && stdenv.cc.libc != null,
+
   # In recent releases, the compiler-rt build seems to produce
   # many `libclang_rt*` libraries, but not a single unified
   # `libcompiler_rt` library, at least under certain configurations. Some
@@ -190,6 +207,11 @@ stdenv.mkDerivation (finalAttrs: {
     lib.optional (stdenv.hostPlatform.isAarch64 && !haveLibc)
       # Fixes https://github.com/NixOS/nixpkgs/issues/393603
       (lib.cmakeBool "COMPILER_RT_DISABLE_AARCH64_FMV" true)
+  ++ lib.optionals withAtomics [
+    (lib.cmakeBool "COMPILER_RT_EXCLUDE_ATOMIC_BUILTIN" (!withAtomicsLib))
+    (lib.cmakeBool "COMPILER_RT_BUILD_STANDALONE_LIBATOMIC" withAtomicsLib)
+    (lib.cmakeBool "COMPILER_RT_LIBATOMIC_USE_PTHREAD" withAtomicsPthread)
+  ]
   ++ devExtraCmakeFlags;
 
   outputs = [
@@ -262,6 +284,11 @@ stdenv.mkDerivation (finalAttrs: {
     ''
     + lib.optionalString forceLinkCompilerRt ''
       ln -s $out/lib/*/libclang_rt.builtins-*.a $out/lib/libcompiler_rt.a
+    ''
+    + lib.optionalString (withAtomics && withAtomicsLib) ''
+      ln -s $out/lib/*/libclang_rt.atomic-*.so $out/lib/libatomic.so
+      # create a link with the original soname as well, so it's found at runtime
+      ln -s $out/lib/*/libclang_rt.atomic-*.so $out/lib/
     '';
 
   meta = llvm_meta // {