opensmtpd.table-passwd: init at 1.0.2

The opensmtpd-extra package has been deprecated in favor of standalone
repositories for each of the filters. Introduce table-passwd, which is
one of these new standalone filters to read login info from "passwd"
files.

pkgs/by-name/op/opensmtpd-table-passwd/package.nix

@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoconf,
+  automake,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "opensmtpd-table-passwd";
+  version = "1.0.2";
+
+  src = fetchFromGitHub {
+    owner = "OpenSMTPD";
+    repo = "table-passwd";
+    tag = finalAttrs.version;
+    hash = "sha256-veE7PADO8KAMEnMrDc9V/xbVMqwF3rUoYPmpQSIJw9o=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+  ];
+
+  configureFlags = [
+    "--sysconfdir=/etc"
+    "--localstatedir=/var"
+    "--with-path-socket=/run"
+    "--with-path-pidfile=/run"
+  ];
+
+  preConfigure = ''
+    sh bootstrap
+  '';
+
+  meta = {
+    homepage = "https://www.opensmtpd.org/";
+    description = "passwd table for the OpenSMTPD mail server";
+    changelog = "https://github.com/OpenSMTPD/table-passwd/releases/tag/${finalAttrs.version}";
+    license = lib.licenses.isc;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [
+      pks
+    ];
+  };
+})