vimPlugins.vim-markdown-composer: move out of vim generated (#366721)

pkgs/applications/editors/vim/plugins/generated.nix

@@ -15993,19 +15993,6 @@ final: prev:
     meta.homepage = "https://github.com/preservim/vim-markdown/";
   };
 
-  vim-markdown-composer = buildVimPlugin {
-    pname = "vim-markdown-composer";
-    version = "2022-06-14";
-    src = fetchFromGitHub {
-      owner = "euclio";
-      repo = "vim-markdown-composer";
-      rev = "e6f99bc20cfcb277c63041b1f766e6d5940bcc76";
-      sha256 = "0ljv8cvca8nk91g67mnzip81say04b1wbj9bzcgzy8m6qkz1r2h3";
-      fetchSubmodules = true;
-    };
-    meta.homepage = "https://github.com/euclio/vim-markdown-composer/";
-  };
-
   vim-markdown-toc = buildVimPlugin {
     pname = "vim-markdown-toc";
     version = "2024-09-01";

pkgs/applications/editors/vim/plugins/overrides.nix

@@ -3342,23 +3342,7 @@ in
     '';
   };
 
-  vim-markdown-composer =
-    let
-      vim-markdown-composer-bin = rustPlatform.buildRustPackage {
-        pname = "vim-markdown-composer-bin";
-        inherit (super.vim-markdown-composer) src version;
-        cargoHash = "sha256-Vie8vLTplhaVU4E9IohvxERfz3eBpd62m8/1Ukzk8e4=";
-        # tests require network access
-        doCheck = false;
-      };
-    in
-    super.vim-markdown-composer.overrideAttrs {
-      preFixup = ''
-        substituteInPlace "$out"/after/ftplugin/markdown/composer.vim \
-          --replace "s:plugin_root . '/target/release/markdown-composer'" \
-          "'${vim-markdown-composer-bin}/bin/markdown-composer'"
-      '';
-    };
+  vim-markdown-composer = callPackage ./vim-markdown-composer { };
 
   vim-matchup = super.vim-matchup.overrideAttrs {
     # Optional treesitter integration

pkgs/applications/editors/vim/plugins/vim-markdown-composer/default.nix

@@ -0,0 +1,49 @@
+{
+  fetchFromGitHub,
+  nix-update-script,
+  rustPlatform,
+  vimUtils,
+}:
+let
+  version = "0-unstable-2022-06-14";
+  src = fetchFromGitHub {
+    owner = "euclio";
+    repo = "vim-markdown-composer";
+    rev = "e6f99bc20cfcb277c63041b1f766e6d5940bcc76";
+    sha256 = "0ljv8cvca8nk91g67mnzip81say04b1wbj9bzcgzy8m6qkz1r2h3";
+    fetchSubmodules = true;
+  };
+
+  vim-markdown-composer-bin = rustPlatform.buildRustPackage {
+    pname = "vim-markdown-composer-bin";
+    inherit src version;
+    cargoHash = "sha256-z5hjY2RUbM5NLfRtyfiHi4PjMnKdAflaZsHw53lgU2E=";
+    # tests require network access
+    doCheck = false;
+  };
+in
+vimUtils.buildVimPlugin {
+  pname = "vim-markdown-composer";
+  inherit version src;
+
+  preFixup = ''
+    substituteInPlace "$out"/after/ftplugin/markdown/composer.vim \
+      --replace-fail \
+      "s:plugin_root . '/target/release/markdown-composer'" \
+      "'${vim-markdown-composer-bin}/bin/markdown-composer'"
+  '';
+
+  passthru = {
+    updateScript = nix-update-script {
+      extraArgs = [ "--version=branch" ];
+      attrPath = "vimPlugins.vim-markdown-composer.vim-markdown-composer-bin";
+    };
+
+    # needed for the update script
+    inherit vim-markdown-composer-bin;
+  };
+
+  meta = {
+    homepage = "https://github.com/euclio/vim-markdown-composer/";
+  };
+}

pkgs/applications/editors/vim/plugins/vim-plugin-names

@@ -1328,7 +1328,6 @@ https://github.com/google/vim-maktaba/,,
 https://github.com/lambdalisue/vim-manpager/,,
 https://github.com/Yilin-Yang/vim-markbar/,,
 https://github.com/preservim/vim-markdown/,,
-https://github.com/euclio/vim-markdown-composer/,,
 https://github.com/mzlogin/vim-markdown-toc/,,
 https://github.com/leafOfTree/vim-matchtag/,HEAD,
 https://github.com/andymass/vim-matchup/,,