coc-wxml: migrate from nodePackages

pkgs/applications/editors/vim/plugins/cocPlugins.nix

@@ -37,6 +37,7 @@
   coc-toml,
   coc-vimlsp,
   coc-vimtex,
+  coc-wxml,
 }:
 final: prev: {
   coc-basedpyright = buildVimPlugin {
@@ -227,4 +228,9 @@ final: prev: {
     inherit (coc-vimtex) pname version meta;
     src = "${coc-vimtex}/lib/node_modules/coc-vimtex";
   };
+
+  coc-wxml = buildVimPlugin {
+    inherit (coc-wxml) pname version meta;
+    src = "${coc-wxml}/lib/node_modules/coc-wxml";
+  };
 }

pkgs/applications/editors/vim/plugins/nodePackagePlugins.nix

@@ -10,7 +10,6 @@ let
     "coc-ltex"
     "coc-tsserver"
     "coc-ultisnips"
-    "coc-wxml"
     "coc-yaml"
     "coc-yank"
     "coc-nginx"

pkgs/by-name/co/coc-wxml/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  fetchYarnDeps,
+  yarnConfigHook,
+  yarnBuildHook,
+  yarnInstallHook,
+  nodejs,
+  nix-update-script,
+}:
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "coc-wxml";
+  version = "1.0.9";
+
+  src = fetchFromGitHub {
+    owner = "neoclide";
+    repo = "coc-wxml";
+    tag = finalAttrs.version;
+    hash = "sha256-6tI+rIgoKGafBSxbPumCquAahJVR3rUzJB4VWQR+qw0=";
+  };
+
+  # Fix yarn.lock file
+  postPatch = ''
+    substituteInPlace yarn.lock \
+      --replace-fail "http://registry.npmjs.org" "https://registry.yarnpkg.com"
+  '';
+
+  yarnOfflineCache = fetchYarnDeps {
+    inherit (finalAttrs) src postPatch;
+    hash = "sha256-s2doN+DeVJPIWe/vOuAH7cYl/S/v8S4yeTG6KIWKphA=";
+  };
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    yarnBuildHook
+    yarnInstallHook
+    nodejs
+  ];
+
+  NODE_OPTIONS = "--openssl-legacy-provider";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Wxml extension for coc.nvim";
+    homepage = "https://github.com/neoclide/coc-wxml";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ pyrox0 ];
+  };
+})

pkgs/development/node-packages/aliases.nix

@@ -114,6 +114,7 @@ mapAliases {
   coc-vetur = throw "coc-vetur was removed because vetur was deprecated by Vue in favor of volar. Use coc-volar instead, which supports Vue 3"; # added 2025-10-01
   inherit (pkgs) coc-vimlsp; # Added 2025-11-05
   inherit (pkgs) coc-vimtex; # Added 2025-11-05
+  inherit (pkgs) coc-wxml; # Added 2025-11-05
   coinmon = throw "coinmon was removed since it was abandoned upstream"; # added 2024-03-19
   coffee-script = pkgs.coffeescript; # added 2023-08-18
   inherit (pkgs) concurrently; # added 2024-08-05

pkgs/development/node-packages/node-packages.json

@@ -25,7 +25,6 @@
 , "coc-ltex"
 , "coc-tsserver"
 , "coc-ultisnips"
-, "coc-wxml"
 , "coc-yaml"
 , "coc-yank"
 , "code-theme-converter"

pkgs/development/node-packages/node-packages.nix

@@ -37077,23 +37077,6 @@ in
     bypassCache = true;
     reconstructLock = true;
   };
-  coc-wxml = nodeEnv.buildNodePackage {
-    name = "coc-wxml";
-    packageName = "coc-wxml";
-    version = "1.0.9";
-    src = fetchurl {
-      url = "https://registry.npmjs.org/coc-wxml/-/coc-wxml-1.0.9.tgz";
-      sha512 = "ExbBjO4/7sbwHVawtK/sDzFwmUTwW9rHgm51sJxqQim+Zjn3vw1x0pNObonVb+r/kX9peLCyE6/nmT2ybfeBPg==";
-    };
-    buildInputs = globalBuildInputs;
-    meta = {
-      description = "wxml language server extension for coc.nvim";
-      license = "MIT";
-    };
-    production = true;
-    bypassCache = true;
-    reconstructLock = true;
-  };
   coc-yaml = nodeEnv.buildNodePackage {
     name = "coc-yaml";
     packageName = "coc-yaml";