nixos/vivid: init module (#345656)

nixos/doc/manual/release-notes/rl-2505.section.md

@@ -67,6 +67,8 @@
 
 - [agorakit](https://github.com/agorakit/agorakit), an organization tool for citizens' collectives. Available with [services.agorakit](options.html#opt-services.agorakit.enable).
 
+- [vivid](https://github.com/sharkdp/vivid), a generator for LS_COLOR. Available as [programs.vivid](#opt-programs.vivid.enable).
+
 - [waagent](https://github.com/Azure/WALinuxAgent), the Microsoft Azure Linux Agent (waagent) manages Linux provisioning and VM interaction with the Azure Fabric Controller. Available with [services.waagent](options.html#opt-services.waagent.enable).
 
 - [duckdns](https://www.duckdns.org), free dynamic DNS. Available with [services.duckdns](options.html#opt-services.duckdns.enable)

nixos/modules/module-list.nix

@@ -317,6 +317,7 @@
   ./programs/usbtop.nix
   ./programs/vim.nix
   ./programs/virt-manager.nix
+  ./programs/vivid.nix
   ./programs/wavemon.nix
   ./programs/wayland/cardboard.nix
   ./programs/wayland/hyprlock.nix

nixos/modules/programs/vivid.nix

@@ -0,0 +1,63 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}:
+
+let
+  cfg = config.programs.vivid;
+in
+{
+  options = {
+    programs.vivid = {
+      enable = lib.mkOption {
+        default = false;
+        description = "Whether to configure LS_COLORS with vivid.";
+        type = lib.types.bool;
+      };
+
+      package = lib.mkPackageOption pkgs "vivid" { example = "vivid"; };
+
+      theme = lib.mkOption {
+        default = "gruvbox-dark-soft";
+        description = "Theme to be used (see `vivid themes`)";
+        example = "solarized-dark";
+        type = lib.types.str;
+      };
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    environment.systemPackages = [ cfg.package ];
+
+    programs =
+      let
+        interactiveShellInit = lib.mkAfter ''
+          export LS_COLORS="$(${lib.getExe cfg.package} generate ${cfg.theme})"
+        '';
+        enableLsColors = lib.mkOverride 999 false;
+      in
+      {
+        bash = {
+          inherit interactiveShellInit enableLsColors;
+        };
+        zsh = {
+          inherit interactiveShellInit enableLsColors;
+        };
+      };
+
+    assertions = [
+      {
+        assertion = !config.programs.bash.enableLsColors;
+        message = "`programs.vivid.enable` is incompatible with `programs.bash.enableLsColors`.";
+      }
+      {
+        assertion = !config.programs.zsh.enableLsColors;
+        message = "`programs.vivid.enable` is incompatible with `programs.zsh.enableLsColors`.";
+      }
+    ];
+  };
+
+  meta.maintainers = with lib.maintainers; [ blackheaven ];
+}