gepetto-viewer-corba: init at 5.8.0

pkgs/by-name/ge/gepetto-viewer-corba/package.nix

@@ -0,0 +1,69 @@
+{
+  boost,
+  cmake,
+  doxygen,
+  fetchFromGitHub,
+  fontconfig,
+  gepetto-viewer,
+  lib,
+  pkg-config,
+  python3Packages,
+  libsForQt5,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gepetto-viewer-corba";
+  version = "5.8.0";
+  pyproject = false; # CMake
+
+  src = fetchFromGitHub {
+    owner = "gepetto";
+    repo = "gepetto-viewer-corba";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-/bpAs4ca/+QjWEGuHhuDT8Ts2Ggg+DZWETZfjho6E0w=";
+  };
+
+  outputs = [
+    "out"
+    "doc"
+  ];
+
+  postPatch = ''
+    substituteInPlace src/CMakeLists.txt \
+      --replace-fail "ARGUMENTS $" "ARGUMENTS -p${python3Packages.omniorbpy}/${python3Packages.python.sitePackages} $" \
+      --replace-fail '$'{CMAKE_SOURCE_DIR}/cmake '$'{JRL_CMAKE_MODULES}
+  '';
+
+  buildInputs = [ libsForQt5.qtbase ];
+
+  nativeBuildInputs = [
+    cmake
+    doxygen
+    libsForQt5.wrapQtAppsHook
+    pkg-config
+    python3Packages.omniorb
+  ];
+
+  propagatedBuildInputs = [
+    python3Packages.boost
+    python3Packages.gepetto-viewer
+    python3Packages.omniorbpy
+  ];
+
+  doCheck = true;
+
+  # Fontconfig error: Cannot load default config file: No such file: (null)
+  env.FONTCONFIG_FILE = "${fontconfig.out}/etc/fonts/fonts.conf";
+
+  # Fontconfig error: No writable cache directories
+  preBuild = "export XDG_CACHE_HOME=$(mktemp -d)";
+
+  meta = {
+    homepage = "https://github.com/gepetto/gepetto-viewer-corba";
+    description = "CORBA client/server for gepetto-viewer.";
+    license = lib.licenses.bsd3;
+    maintainers = [ lib.maintainers.nim65s ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/top-level/python-packages.nix

@@ -4982,6 +4982,10 @@ self: super: with self; {
 
   georss-wa-dfes-client = callPackage ../development/python-modules/georss-wa-dfes-client { };
 
+  gepetto-gui = toPythonModule (gepetto-viewer.withPlugins [ gepetto-viewer-corba ]);
+
+  gepetto-viewer-corba = toPythonModule (pkgs.gepetto-viewer-corba.override { python3Packages = self; });
+
   gepetto-viewer = toPythonModule (pkgs.gepetto-viewer.override { python3Packages = self; });
 
   gerbonara = callPackage ../development/python-modules/gerbonara { };