kubazip: init at 0.3.5; tic-80: use system kubazip (#455282)

pkgs/by-name/ku/kubazip/package.nix

@@ -0,0 +1,44 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cmake,
+  ninja,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kubazip";
+  version = "0.3.5";
+
+  src = fetchFromGitHub {
+    owner = "kuba--";
+    repo = "zip";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-wNkIYuwwXo7v3vNaOnRZt1tcd0RGjDvCUqDGdvJzVdo=";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_SHARED_LIBS" (!stdenv.hostPlatform.isStatic))
+  ];
+
+  doCheck = true;
+
+  meta = {
+    description = "Portable, simple zip library written in C";
+    homepage = "https://github.com/kuba--/zip";
+    changelog = "https://github.com/kuba--/zip/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ marcin-serwin ];
+  };
+})

pkgs/by-name/ti/tic-80/package.nix

@@ -7,6 +7,7 @@
   rake,
   curl,
   fetchFromGitHub,
+  kubazip,
   libGL,
   libGLU,
   libX11,
@@ -37,7 +38,7 @@ stdenv.mkDerivation {
     hash = "sha256-UjBnXxYZ5gfk58sI1qek5fkKpJ7LzOVmrxdjVgONcXc=";
     # TIC-80 vendors its dependencies as submodules. For the following dependencies,
     # there are no (or no compatible) packages in nixpkgs yet, so we use the vendored
-    # ones as a fill-in: kubazip, wasm, squirrel, pocketpy, argparse, naett,
+    # ones as a fill-in: wasm, squirrel, pocketpy, argparse, naett,
     # sdlgpu, mruby.
     fetchSubmodules = true;
   };
@@ -90,6 +91,7 @@ stdenv.mkDerivation {
     rake
   ];
   buildInputs = [
+    kubazip
     libGL
     libGLU
     libX11