libdmx: refactor and migrate to pkgs/by-name from xorg namespace

libdmx has been deprecated by upstream, but I can't remove it yet because xdpyinfo still depends on it

pkgs/by-name/li/libdmx/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  xorgproto,
+  libx11,
+  libxext,
+  testers,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "libdmx";
+  version = "1.1.5";
+
+  src = fetchurl {
+    url = "mirror://xorg/individual/lib/libdmx-${finalAttrs.version}.tar.xz";
+    hash = "sha256-NaTiaosLK0/jZEHcpGNkXD+lLSgqw1IFAaOOqULL908=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    xorgproto
+    libx11
+    libxext
+  ];
+
+  configureFlags = lib.optional (
+    stdenv.hostPlatform != stdenv.buildPlatform
+  ) "--enable-malloc0returnsnull";
+
+  passthru = {
+    # updateScript = # libdmx it deprecated and thus needs no updatescript
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = {
+    description = "Xlib-based library for the DMX (Distributed Multihead X) extension";
+    longDescription = ''
+      This library allows X11 clients to use the Distributed Multihead X (DMX) Extension,
+      as previously implemented in the Xdmx server.
+      X.Org removed support for the Xdmx server from the xorg-server releases in the version 21
+      release in 2021. This library is thus now considered deprecated and the version 1.1.5 release
+      is the last release X.Org plans to make of libdmx.
+    '';
+    homepage = "https://gitlab.freedesktop.org/xorg/lib/libdmx";
+    license = lib.licenses.mit;
+    maintainers = [ ];
+    pkgConfigModules = [ "dmx" ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/servers/x11/xorg/default.nix

@@ -8,6 +8,7 @@
   ico,
   imake,
   libapplewm,
+  libdmx,
   libpciaccess,
   libpthread-stubs,
   libx11,
@@ -39,6 +40,7 @@ self: with self; {
     gccmakedep
     ico
     imake
+    libdmx
     libpciaccess
     libxcb
     libxcvt
@@ -2888,44 +2890,6 @@ self: with self; {
     })
   ) { };
 
-  # THIS IS A GENERATED FILE.  DO NOT EDIT!
-  libdmx = callPackage (
-    {
-      stdenv,
-      pkg-config,
-      fetchurl,
-      xorgproto,
-      libX11,
-      libXext,
-      testers,
-    }:
-    stdenv.mkDerivation (finalAttrs: {
-      pname = "libdmx";
-      version = "1.1.5";
-      builder = ./builder.sh;
-      src = fetchurl {
-        url = "mirror://xorg/individual/lib/libdmx-1.1.5.tar.xz";
-        sha256 = "0kzprd1ak3m3042m5hra50nsagswciis9p21ckilyaqbidmf591m";
-      };
-      hardeningDisable = [
-        "bindnow"
-        "relro"
-      ];
-      strictDeps = true;
-      nativeBuildInputs = [ pkg-config ];
-      buildInputs = [
-        xorgproto
-        libX11
-        libXext
-      ];
-      passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
-      meta = {
-        pkgConfigModules = [ "dmx" ];
-        platforms = lib.platforms.unix;
-      };
-    })
-  ) { };
-
   # THIS IS A GENERATED FILE.  DO NOT EDIT!
   libfontenc = callPackage (
     {

pkgs/servers/x11/xorg/generate-expr-from-tarballs.pl

@@ -36,6 +36,7 @@ $pcMap{"gl"} = "libGL";
 $pcMap{"GL"} = "libGL";
 $pcMap{"gbm"} = "libgbm";
 $pcMap{"hwdata"} = "hwdata";
+$pcMap{"dmx"} = "libdmx";
 $pcMap{"fontutil"} = "fontutil";
 $pcMap{"pciaccess"} = "libpciaccess";
 $pcMap{"pthread-stubs"} = "libpthreadstubs";
@@ -293,6 +294,7 @@ print OUT <<EOF;
   ico,
   imake,
   libapplewm,
+  libdmx,
   libpciaccess,
   libpthread-stubs,
   libx11,
@@ -324,6 +326,7 @@ self: with self; {
     gccmakedep
     ico
     imake
+    libdmx
     libpciaccess
     libxcb
     libxcvt

pkgs/servers/x11/xorg/overrides.nix

@@ -179,9 +179,6 @@ self: super:
   libXxf86misc = super.libXxf86misc.overrideAttrs (attrs: {
     configureFlags = attrs.configureFlags or [ ] ++ malloc0ReturnsNullCrossFlag;
   });
-  libdmx = super.libdmx.overrideAttrs (attrs: {
-    configureFlags = attrs.configureFlags or [ ] ++ malloc0ReturnsNullCrossFlag;
-  });
   libFS = super.libFS.overrideAttrs (attrs: {
     configureFlags = attrs.configureFlags or [ ] ++ malloc0ReturnsNullCrossFlag;
   });

pkgs/servers/x11/xorg/tarballs.list

@@ -153,7 +153,6 @@ mirror://xorg/individual/font/font-sony-misc-1.0.4.tar.xz
 mirror://xorg/individual/font/font-sun-misc-1.0.4.tar.xz
 mirror://xorg/individual/font/font-winitzki-cyrillic-1.0.4.tar.xz
 mirror://xorg/individual/font/font-xfree86-type1-1.0.5.tar.xz
-mirror://xorg/individual/lib/libdmx-1.1.5.tar.xz
 mirror://xorg/individual/lib/libfontenc-1.1.8.tar.xz
 mirror://xorg/individual/lib/libFS-1.0.10.tar.xz
 mirror://xorg/individual/lib/libICE-1.1.2.tar.xz