television: init at 0.5.0

2024-11-20 20:32:42 +01:00
parent 5c65b89442
commit ddb939709f
1 changed files with 49 additions and 0 deletions
@@ -0,0 +1,49 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  testers,
+  television,
+  nix-update-script,
+}:
+rustPlatform.buildRustPackage rec {
+  pname = "television";
+  version = "0.5.0";
+
+  src = fetchFromGitHub {
+    owner = "alexpasmantier";
+    repo = "television";
+    rev = "refs/tags/" + version;
+    hash = "sha256-yi8lPm3zkmamN6gPlGfojNlIXM1cgSr1zL2zMNni5f0=";
+  };
+
+  cargoHash = "sha256-1SdyVtMjkfXH9iGew9i8xpx8WlUly4vIcKY3weeW3LQ=";
+
+  passthru = {
+    tests.version = testers.testVersion {
+      package = television;
+      command = "XDG_DATA_HOME=$TMPDIR tv --version";
+    };
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Television is a blazingly fast general purpose fuzzy finder";
+
+    longDescription = ''
+      Television is a blazingly fast general purpose fuzzy finder TUI written
+      in Rust. It is inspired by the neovim telescope plugin and is designed
+      to be fast, efficient, simple to use and easily extensible. It is built
+      on top of tokio, ratatui and the nucleo matcher used by the helix editor.
+    '';
+
+    homepage = "https://github.com/alexpasmantier/television";
+    changelog = "https://github.com/alexpasmantier/television/releases/tag/${version}";
+    license = lib.licenses.mit;
+    mainProgram = "tv";
+    maintainers = with lib.maintainers; [
+      louis-thevenet
+      getchoo
+    ];
+  };
+}