python312Packages.deltachat-rpc-client: init

pkgs/development/python-modules/deltachat-rpc-client/default.nix

@@ -0,0 +1,38 @@
+{
+  buildPythonPackage,
+  deltachat-rpc-server,
+  imap-tools,
+  lib,
+  pytestCheckHook,
+  setuptools,
+}:
+
+buildPythonPackage rec {
+  pname = "deltachat-rpc-client";
+  inherit (deltachat-rpc-server) version src;
+  pyproject = true;
+
+  sourceRoot = "${src.name}/deltachat-rpc-client";
+
+  postPatch = ''
+    substituteInPlace src/deltachat_rpc_client/rpc.py \
+      --replace-fail deltachat-rpc-server "${lib.getExe deltachat-rpc-server}"
+  '';
+
+  build-system = [ setuptools ];
+
+  dependencies = [ imap-tools ];
+
+  pythonImportsCheck = [ "deltachat_rpc_client" ];
+
+  nativeCheckInputs = [ pytestCheckHook ];
+
+  # requires a chatmail server
+  doCheck = false;
+
+  meta = {
+    inherit (deltachat-rpc-server.meta) changelog license maintainers;
+    description = "Python client for Delta Chat core JSON-RPC interface";
+    homepage = "https://github.com/deltachat/deltachat-core-rust/tree/main/deltachat-rpc-client";
+  };
+}

pkgs/top-level/python-packages.nix

@@ -3027,6 +3027,8 @@ self: super: with self; {
 
   deltachat = callPackage ../development/python-modules/deltachat { };
 
+  deltachat-rpc-client = callPackage ../development/python-modules/deltachat-rpc-client { };
+
   deltachat2 = callPackage ../development/python-modules/deltachat2 { };
 
   deltalake = callPackage ../development/python-modules/deltalake { };