soapyplutosdr: init at 0.2.2 (#322280)

pkgs/by-name/so/soapyplutosdr/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  darwin,
+  libad9361,
+  libiio,
+  libusb1,
+  soapysdr,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "soapyplutosdr";
+  version = "0.2.2";
+
+  src = fetchFromGitHub {
+    owner = "pothosware";
+    repo = "SoapyPlutoSDR";
+    rev = "soapy-plutosdr-${finalAttrs.version}";
+    hash = "sha256-uXKvv/QRbYknqsLGlPFxSH7KLh0CucLjq4XEFFcieWw=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+  buildInputs =
+    [
+      libad9361
+      libiio
+      libusb1
+      soapysdr
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isDarwin [
+      darwin.apple_sdk.frameworks.Security
+      darwin.apple_sdk.frameworks.IOKit
+      darwin.libobjc
+    ];
+
+  cmakeFlags = [ "-DSoapySDR_DIR=${soapysdr}/share/cmake/SoapySDR/" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/pothosware/SoapyPlutoSDR";
+    changelog = "https://github.com/pothosware/SoapyPlutoSDR/blob/soapy-plutosdr-${finalAttrs.version}/Changelog.txt";
+    description = "SoapySDR plugin for Pluto SDR devices";
+    license = licenses.lgpl21;
+    maintainers = with maintainers; [ wucke13 ];
+    platforms = platforms.unix;
+  };
+})

pkgs/top-level/all-packages.nix

@@ -10659,6 +10659,7 @@ with pkgs;
       soapyaudio
       soapybladerf
       soapyhackrf
+      soapyplutosdr
       soapyremote
       soapyrtlsdr
       soapyuhd