libdisplay-info{,_0_2}: make generic, libdisplay-info_0_3: init at 0.3.0, niri: pin libdisplay-info_0_3 (#546004)

pkgs/by-name/li/libdisplay-info/0.2.nix

@@ -0,0 +1,4 @@
+import ./generic.nix {
+  version = "0.2.0";
+  hash = "sha256-6xmWBrPHghjok43eIDGeshpUEQTuwWLXNHg7CnBUt3Q=";
+}

pkgs/by-name/li/libdisplay-info/0.3.nix

@@ -0,0 +1,4 @@
+import ./generic.nix {
+  version = "0.3.0";
+  hash = "sha256-nXf2KGovNKvcchlHlzKBkAOeySMJXgxMpbi5z9gLrdc=";
+}

pkgs/by-name/li/libdisplay-info/generic.nix

@@ -0,0 +1,59 @@
+{
+  version,
+  hash,
+}:
+
+{
+  lib,
+  stdenv,
+  buildPackages,
+  fetchFromGitLab,
+  meson,
+  pkg-config,
+  ninja,
+  python3,
+  hwdata,
+  v4l-utils,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "libdisplay-info";
+  inherit version;
+
+  src = fetchFromGitLab {
+    inherit hash;
+    domain = "gitlab.freedesktop.org";
+    owner = "emersion";
+    repo = "libdisplay-info";
+    tag = finalAttrs.version;
+  };
+
+  strictDeps = true;
+  __structuredAttrs = true;
+
+  depsBuildBuild = [ pkg-config ];
+  nativeBuildInputs = [
+    meson
+    pkg-config
+    ninja
+    hwdata
+    python3
+  ]
+  ++ lib.optionals (stdenv.hostPlatform.emulatorAvailable buildPackages) [
+    # Only used for tests, which we cannot run without an emulator
+    v4l-utils
+  ];
+
+  postPatch = ''
+    patchShebangs tool/gen-search-table.py
+  '';
+
+  meta = {
+    description = "EDID and DisplayID library";
+    mainProgram = "di-edid-decode";
+    homepage = "https://gitlab.freedesktop.org/emersion/libdisplay-info";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.linux ++ lib.platforms.freebsd;
+    maintainers = with lib.maintainers; [ pedrohlc ];
+  };
+})

pkgs/by-name/li/libdisplay-info/package.nix

@@ -1,51 +1,4 @@
-{
-  lib,
-  stdenv,
-  buildPackages,
-  fetchFromGitLab,
-  meson,
-  pkg-config,
-  ninja,
-  python3,
-  hwdata,
-  v4l-utils,
-}:
-
-stdenv.mkDerivation (finalAttrs: {
-  pname = "libdisplay-info";
+import ./generic.nix {
   version = "0.4.0";
-
-  src = fetchFromGitLab {
-    domain = "gitlab.freedesktop.org";
-    owner = "emersion";
-    repo = "libdisplay-info";
-    rev = finalAttrs.version;
-    sha256 = "sha256-5wd7UUYfhlvhAGfWWa/O14Did7pEmhwSMeXiYoYx1vU=";
-  };
-
-  depsBuildBuild = [ pkg-config ];
-  nativeBuildInputs = [
-    meson
-    pkg-config
-    ninja
-    hwdata
-    python3
-  ]
-  ++ lib.optionals (stdenv.hostPlatform.emulatorAvailable buildPackages) [
-    # Only used for tests, which we cannot run without an emulator
-    v4l-utils
-  ];
-
-  postPatch = ''
-    patchShebangs tool/gen-search-table.py
-  '';
-
-  meta = {
-    description = "EDID and DisplayID library";
-    mainProgram = "di-edid-decode";
-    homepage = "https://gitlab.freedesktop.org/emersion/libdisplay-info";
-    license = lib.licenses.mit;
-    platforms = lib.platforms.linux ++ lib.platforms.freebsd;
-    maintainers = with lib.maintainers; [ pedrohlc ];
-  };
-})
+  hash = "sha256-5wd7UUYfhlvhAGfWWa/O14Did7pEmhwSMeXiYoYx1vU=";
+}

pkgs/by-name/li/libdisplay-info_0_2/package.nix

@@ -1,18 +0,0 @@
-{
-  libdisplay-info,
-  fetchFromGitLab,
-}:
-
-libdisplay-info.overrideAttrs (
-  finalAttrs: oldAttrs: {
-    version = "0.2.0";
-
-    src = fetchFromGitLab {
-      domain = "gitlab.freedesktop.org";
-      owner = "emersion";
-      repo = "libdisplay-info";
-      rev = finalAttrs.version;
-      sha256 = "sha256-6xmWBrPHghjok43eIDGeshpUEQTuwWLXNHg7CnBUt3Q=";
-    };
-  }
-)

pkgs/by-name/ni/niri/package.nix

@@ -4,7 +4,7 @@
   eudev,
   fetchFromGitHub,
   installShellFiles,
-  libdisplay-info,
+  libdisplay-info_0_3,
   libglvnd,
   libinput,
   libxkbcommon,
@@ -58,7 +58,7 @@ rustPlatform.buildRustPackage (finalAttrs: {
   ];
 
   buildInputs = [
-    libdisplay-info
+    libdisplay-info_0_3
     libglvnd # For libEGL
     libinput
     libxkbcommon

pkgs/top-level/all-packages.nix

@@ -5991,6 +5991,9 @@ with pkgs;
   libdbusmenu-gtk2 = libdbusmenu.override { gtkVersion = "2"; };
   libdbusmenu-gtk3 = libdbusmenu.override { gtkVersion = "3"; };
 
+  libdisplay-info_0_2 = callPackage ../by-name/li/libdisplay-info/0.2.nix { };
+  libdisplay-info_0_3 = callPackage ../by-name/li/libdisplay-info/0.3.nix { };
+
   dwarfdump = libdwarf.bin;
 
   libfm-extra = libfm.override {