postfixadmin: init at 4.0.1

This commit reintroduces postfixadmin after having been removed in
2cb89c0aef. I am only able to take over
maintainership of the package, but not the NixOS module
`services.postfixadmin` at the moment.

https://github.com/postfixadmin/postfixadmin/releases/tag/v4.0.1

pkgs/by-name/po/postfixadmin/package.nix

@@ -0,0 +1,44 @@
+{
+  fetchFromGitHub,
+  lib,
+  php84,
+}:
+
+let
+  php = php84;
+in
+php.buildComposerProject2 (finalAttrs: {
+  pname = "postfixadmin";
+  version = "4.0.1";
+
+  src = fetchFromGitHub {
+    owner = "postfixadmin";
+    repo = "postfixadmin";
+    tag = "postfixadmin-${finalAttrs.version}";
+    hash = "sha256-mr5FBURTGP2J3JMlcexXjz4GFJNqPR4rZyqHVN7+6iM=";
+  };
+
+  vendorHash = "sha256-gv6QYuHGo2r2WgtLPLco/PmKxYSijDkpWoF/vIR5y5s=";
+
+  # Upstream does not ship a lock file, we have to maintain our own for now.
+  # https://github.com/postfixadmin/postfixadmin/issues/948
+  composerLock = ./composer.lock;
+
+  postInstall = ''
+    out_dir="$out"/share/php/postfixadmin/
+
+    ln -sf /etc/postfixadmin/config.local.php "$out_dir"
+    ln -sf /var/cache/postfixadmin/templates_c "$out_dir"
+  '';
+
+  passthru.phpPackage = php;
+
+  meta = {
+    changelog = "https://github.com/postfixadmin/postfixadmin/releases/tag/${finalAttrs.src.tag}";
+    description = "Web based virtual user administration interface for Postfix mail servers";
+    homepage = "https://postfixadmin.sourceforge.io/";
+    maintainers = with lib.maintainers; [ yayayayaka ];
+    license = lib.licenses.gpl2Plus;
+    platforms = lib.platforms.all;
+  };
+})

pkgs/top-level/aliases.nix

@@ -1215,7 +1215,6 @@ mapAliases {
   polypane = throw "'polypane' has been removed due to lack of maintenance in nixpkgs"; # Added 2025-06-25
   poppler_utils = throw "'poppler_utils' has been renamed to/replaced by 'poppler-utils'"; # Converted to throw 2025-10-27
   posterazor = throw "posterazor was removed due to numerous vulnerabilities in freeimage"; # Added 2025-10-23
-  postfixadmin = throw "'postfixadmin' has been removed due to lack of maintenance and missing support for PHP >8.1"; # Added 2025-10-03
   postgis = throw "'postgis' has been removed. Use 'postgresqlPackages.postgis' instead."; # Added 2025-07-19
   postgres-lsp = lib.warnOnInstantiate "'postgres-lsp' has been renamed to 'postgres-language-server'" postgres-language-server; # Added 2025-10-28
   postgresql13JitPackages = throw "'postgresql13JitPackages' has been renamed to/replaced by 'postgresql13Packages'"; # Converted to throw 2025-10-27