moneydance: fix GTK crash

This fixes a bug reported to me offline. When running without GDK/GTK
environment setup (e.g. under Plasma where XDG_DATA_DIRS doesn't point
to any GLib schema paths), the JVM would crash with the error: No
GSettings schemas are installed on the system.

pkgs/by-name/mo/moneydance/package.nix

@@ -1,9 +1,11 @@
 {
   lib,
   stdenv,
+  buildPackages,
   fetchzip,
   makeWrapper,
   openjdk23,
+  wrapGAppsHook3,
   jvmFlags ? [ ],
 }:
 let
@@ -20,8 +22,25 @@ stdenv.mkDerivation (finalAttrs: {
     hash = "sha256-wwSb3CuhuXB4I9jq+TpLPbd1k9UzqQbAaZkGKgi+nns=";
   };
 
-  nativeBuildInputs = [ makeWrapper ];
+  # We must use wrapGAppsHook (since Java GUIs on Linux use GTK), but by
+  # default that uses makeBinaryWrapper which doesn't support flags that need
+  # quoting: <https://github.com/NixOS/nixpkgs/issues/330471>. Thanks to
+  # @Artturin for the tip to override the wrapper generator.
+  nativeBuildInputs = [
+    makeWrapper
+    (buildPackages.wrapGAppsHook3.override { makeWrapper = buildPackages.makeShellWrapper; })
+  ];
   buildInputs = [ jdk ];
+  dontWrapGApps = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/libexec $out/bin
+    cp -p $src/lib/* $out/libexec/
+
+    runHook postInstall
+  '';
 
   # Note the double escaping in the call to makeWrapper. The escapeShellArgs
   # call quotes each element of the flags list as a word[1] and returns a
@@ -31,7 +50,7 @@ stdenv.mkDerivation (finalAttrs: {
   #
   # 1. https://www.gnu.org/software/bash/manual/html_node/Word-Splitting.html
   # 2. https://github.com/NixOS/nixpkgs/blob/master/pkgs/build-support/setup-hooks/make-wrapper.sh
-  installPhase =
+  postFixup =
     let
       finalJvmFlags = [
         "-client"
@@ -42,14 +61,10 @@ stdenv.mkDerivation (finalAttrs: {
       ] ++ jvmFlags ++ [ "Moneydance" ];
     in
     ''
-      runHook preInstall
-
-      mkdir -p $out/libexec $out/bin
-      cp -p $src/lib/* $out/libexec/
+      # This is in postFixup because gappsWrapperArgs is generated in preFixup
       makeWrapper ${jdk}/bin/java $out/bin/moneydance \
+        "''${gappsWrapperArgs[@]}" \
         --add-flags ${lib.escapeShellArg (lib.escapeShellArgs finalJvmFlags)}
-
-      runHook postInstall
     '';
 
   passthru = {