souffle: add some package tests

pkgs/development/compilers/souffle/default.nix

@@ -1,7 +1,7 @@
 { lib, stdenv, fetchFromGitHub
 , bash-completion, perl, ncurses, zlib, sqlite, libffi
 , mcpp, cmake, bison, flex, doxygen, graphviz
-, makeWrapper, python3
+, makeWrapper, python3, callPackage
 }:
 
 
@@ -51,6 +51,8 @@ stdenv.mkDerivation rec {
 
   outputs = [ "out" ];
 
+  passthru.tests = callPackage ./tests.nix { };
+
   meta = with lib; {
     description = "Translator of declarative Datalog programs into the C++ language";
     homepage    = "https://souffle-lang.github.io/";

pkgs/development/compilers/souffle/tests.nix

@@ -0,0 +1,36 @@
+{ stdenv, lib, souffle, runCommand }:
+let
+  simpleTest = { name, commands }:
+    stdenv.mkDerivation {
+      inherit name;
+      meta.timeout = 60;
+      buildCommand = ''
+        echo -e '.decl A(X: number)\n.output A\nA(1).' > A.dl
+        ${commands}
+        [ "$(cat A.csv)" = "1" ]
+        touch $out
+      '';
+    };
+in {
+  interpret = simpleTest {
+    name = "souffle-test-interpret";
+    commands = "${souffle}/bin/souffle A.dl";
+  };
+
+  compile-in-one-step = simpleTest {
+    name = "souffle-test-compile-in-one-step";
+    commands = ''
+      ${souffle}/bin/souffle -o A A.dl
+      ./A
+    '';
+  };
+
+  compile-in-two-steps = simpleTest {
+    name = "souffle-test-compile-in-two-steps";
+    commands = ''
+      ${souffle}/bin/souffle -g A.cpp A.dl
+      ${souffle}/bin/souffle-compile.py A.cpp -o A
+      ./A
+    '';
+  };
+}