python3Packages.tsid: depend on pkgs.tsid

instead of rebuild, use the new BUILD_STANDALONE_PYTHON_INTERFACE feature.

pkgs/by-name/ts/tsid/package.nix

@@ -9,8 +9,6 @@
   pinocchio,
   proxsuite,
   stdenv,
-  pythonSupport ? false,
-  python3Packages,
 }:
 
 stdenv.mkDerivation (finalAttrs: {
@@ -25,7 +23,7 @@ stdenv.mkDerivation (finalAttrs: {
   };
 
   cmakeFlags = [
-    (lib.cmakeBool "BUILD_PYTHON_INTERFACE" pythonSupport)
+    (lib.cmakeBool "BUILD_PYTHON_INTERFACE" false)
     (lib.cmakeBool "BUILD_WITH_OSQP" true)
     (lib.cmakeBool "BUILD_WITH_PROXQP" true)
     (lib.cmakeBool "INSTALL_DOCUMENTATION" true)
@@ -40,22 +38,16 @@ stdenv.mkDerivation (finalAttrs: {
     doxygen
     cmake
     pkg-config
-  ]
-  ++ lib.optionals pythonSupport [
-    python3Packages.python
-    python3Packages.pythonImportsCheckHook
   ];
 
   propagatedBuildInputs = [
     eiquadprog
     osqp-eigen
+    pinocchio
     proxsuite
-  ]
-  ++ lib.optional (!pythonSupport) pinocchio
-  ++ lib.optional pythonSupport python3Packages.pinocchio;
+  ];
 
   doCheck = true;
-  pythonImportsCheck = [ "tsid" ];
 
   meta = {
     description = "Efficient Task Space Inverse Dynamics (TSID) based on Pinocchio";

pkgs/development/python-modules/tsid/default.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+
+  toPythonModule,
+  pythonImportsCheckHook,
+
+  tsid,
+
+  pinocchio,
+  python,
+}:
+toPythonModule (
+  tsid.overrideAttrs (super: {
+    pname = "py-${super.pname}";
+
+    cmakeFlags = super.cmakeFlags ++ [
+      (lib.cmakeBool "BUILD_PYTHON_INTERFACE" true)
+      (lib.cmakeBool "BUILD_STANDALONE_PYTHON_INTERFACE" true)
+    ];
+
+    # those are used by CMake at configure/build time
+    nativeBuildInputs = super.nativeBuildInputs ++ [
+      python
+    ];
+
+    propagatedBuildInputs = super.propagatedBuildInputs ++ [
+      pinocchio
+      tsid
+    ];
+
+    nativeCheckInputs = [
+      pythonImportsCheckHook
+    ];
+
+    pythonImportsCheck = [
+      "tsid"
+    ];
+  })
+)

pkgs/top-level/python-packages.nix

@@ -18825,12 +18825,7 @@ self: super: with self; {
 
   tsfresh = callPackage ../development/python-modules/tsfresh { };
 
-  tsid = toPythonModule (
-    pkgs.tsid.override {
-      pythonSupport = true;
-      python3Packages = self;
-    }
-  );
+  tsid = callPackage ../development/python-modules/tsid { inherit (pkgs) tsid; };
 
   tskit = callPackage ../development/python-modules/tskit { };