Merge pull request #331845 from TomaSajt/nutils

python312Packages.nutils: unbreak by adding missing deps; python312Packages.nutils-poly: init

pkgs/development/python-modules/nutils-poly/default.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenv,
+  buildPythonPackage,
+  fetchFromGitHub,
+  rustPlatform,
+  libiconv,
+  numpy,
+  unittestCheckHook,
+  pythonOlder,
+}:
+
+buildPythonPackage rec {
+  pname = "nutils-poly";
+  version = "1.0.1";
+  pyproject = true;
+
+  disabled = pythonOlder "3.8";
+
+  src = fetchFromGitHub {
+    owner = "nutils";
+    repo = "poly-py";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-dxFv4Az3uz6Du5dk5KZJ+unVbt3aZjxXliAQZhmBWDM=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoTarball {
+    name = "${pname}-${version}";
+    inherit src;
+    hash = "sha256-+fnKvlSwM197rsyusFH7rs1W6livxel45UGbi1sB05k=";
+  };
+
+  nativeBuildInputs = [ rustPlatform.cargoSetupHook ];
+
+  buildInputs = lib.optionals stdenv.isDarwin [ libiconv ];
+
+  build-system = [ rustPlatform.maturinBuildHook ];
+
+  dependencies = [ numpy ];
+
+  nativeCheckInputs = [ unittestCheckHook ];
+
+  pythonImportsCheck = [ "nutils_poly" ];
+
+  meta = {
+    description = "Low-level functions for evaluating and manipulating polynomials";
+    homepage = "https://github.com/nutils/poly-py";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ tomasajt ];
+  };
+}

pkgs/development/python-modules/nutils/default.nix

@@ -2,11 +2,14 @@
   lib,
   buildPythonPackage,
   fetchFromGitHub,
-  numpy,
-  treelog,
-  stringly,
   flit-core,
+  appdirs,
   bottombar,
+  numpy,
+  nutils-poly,
+  psutil,
+  stringly,
+  treelog,
   pytestCheckHook,
   pythonOlder,
 }:
@@ -14,9 +17,9 @@
 buildPythonPackage rec {
   pname = "nutils";
   version = "8.7";
-  format = "pyproject";
+  pyproject = true;
 
-  disabled = pythonOlder "3.7";
+  disabled = pythonOlder "3.8";
 
   src = fetchFromGitHub {
     owner = "evalf";
@@ -25,15 +28,20 @@ buildPythonPackage rec {
     hash = "sha256-wxouS0FXrdIhm6nTVBuzkwHceJnZ7f7k8nMFxFsZchE=";
   };
 
-  nativeBuildInputs = [ flit-core ];
+  build-system = [ flit-core ];
 
-  propagatedBuildInputs = [
-    numpy
-    treelog
-    stringly
+  dependencies = [
+    appdirs
     bottombar
+    numpy
+    nutils-poly
+    psutil
+    stringly
+    treelog
   ];
 
+  pythonRelaxDeps = [ "psutil" ];
+
   nativeCheckInputs = [ pytestCheckHook ];
 
   pythonImportsCheck = [ "nutils" ];

pkgs/top-level/python-packages.nix

@@ -9247,6 +9247,8 @@ self: super: with self; {
 
   nutils = callPackage ../development/python-modules/nutils { };
 
+  nutils-poly = callPackage ../development/python-modules/nutils-poly { };
+
   nvchecker = callPackage ../development/python-modules/nvchecker { };
 
   nvdlib = callPackage ../development/python-modules/nvdlib { };