jsonplaceholder: migrate from nodePackages (#458659)

pkgs/by-name/js/jsonplaceholder/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  buildNpmPackage,
+  fetchFromGitHub,
+  makeBinaryWrapper,
+  nodejs,
+  nix-update-script,
+}:
+
+buildNpmPackage {
+  pname = "jsonplaceholder";
+  version = "0-unstable-2021-06-14";
+
+  src = fetchFromGitHub {
+    owner = "typicode";
+    repo = "jsonplaceholder";
+    rev = "7ae4432ac3f60e7226a899c25e04826207d07098";
+    hash = "sha256-b+p1bByq0oRj3zqVsFFoXFR2ydrbZqWwJdVIaXEmQwQ";
+  };
+
+  npmDepsHash = "sha256-x+EN33CQE4ga9T0V4oJRPkELT8x4WbNIsQmvyW+hHi8=";
+
+  nativeBuildInputs = [ makeBinaryWrapper ];
+
+  postInstall = ''
+    rm -rf $out/lib/node_modules/jsonplaceholder/node_modules/.bin
+
+    makeWrapper ${nodejs}/bin/node $out/bin/jsonplaceholder \
+      --add-flags $out/lib/node_modules/jsonplaceholder/index.js \
+      --set NODE_PATH "$out/lib/node_modules"
+  '';
+
+  passthru.updateScript = nix-update-script { extraArgs = [ "--version=branch" ]; };
+
+  meta = {
+    description = "Simple online fake REST API server";
+    homepage = "https://jsonplaceholder.typicode.com/";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ pyrox0 ];
+  };
+}

pkgs/development/node-packages/aliases.nix

@@ -145,6 +145,7 @@ mapAliases {
   ionic = throw "ionic was replaced by @ionic/cli"; # added 2023-08-19
   inherit (pkgs) jake; # added 2023-08-19
   inherit (pkgs) javascript-typescript-langserver; # added 2023-08-19
+  inherit (pkgs) jsonplaceholder; # Added 2025-11-04
   inherit (pkgs) kaput-cli; # added 2024-12-03
   karma = pkgs.karma-runner; # added 2023-07-29
   keyoxide = pkgs.keyoxide-cli; # Added 2025-10-20

pkgs/development/node-packages/node-packages.json

@@ -90,7 +90,6 @@
 , "json-refs"
 , "json-server"
 , "jsonlint"
-, "jsonplaceholder"
 , "katex"
 , "lcov-result-merger"
 , "live-server"

pkgs/development/node-packages/overrides.nix

@@ -98,19 +98,6 @@ final: prev: {
     };
   });
 
-  jsonplaceholder = prev.jsonplaceholder.override {
-    buildInputs = [ nodejs ];
-    postInstall = ''
-      exe=$out/bin/jsonplaceholder
-      mkdir -p $out/bin
-      cat >$exe <<EOF
-      #!${pkgs.runtimeShell}
-      exec -a jsonplaceholder ${nodejs}/bin/node $out/lib/node_modules/jsonplaceholder/index.js
-      EOF
-      chmod a+x $exe
-    '';
-  };
-
   makam = prev.makam.override {
     nativeBuildInputs = [ pkgs.buildPackages.makeWrapper ];
     postFixup = ''