zenoh-c/zenoh-cpp: init at 1.4.0 (#415528)

2025-06-11 23:42:24 +02:00
parent 876b962775 aacdb4fdb1
commit bd3a2b9f7e
2 changed files with 100 additions and 0 deletions
@@ -0,0 +1,53 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  cargo,
+  rustPlatform,
+  rustc,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "zenoh-c";
+  version = "1.4.0"; # nixpkgs-update: no auto update
+
+  src = fetchFromGitHub {
+    owner = "eclipse-zenoh";
+    repo = "zenoh-c";
+    tag = version;
+    hash = "sha256-Mn3diwJgMkYXP9Dn5AqquN1UJ+P+b4QadiXqzzYZK+o=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit src pname version;
+    hash = "sha256-Z9xKC7svGPSuQm4KCKOfGAFOdWgSjBK+/LFT3rAebTg=";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    cargo
+    rustPlatform.cargoSetupHook
+    rustc
+  ];
+
+  postInstall = ''
+    substituteInPlace $out/lib/pkgconfig/zenohc.pc \
+      --replace-fail "\''${prefix}/" ""
+  '';
+
+  meta = {
+    description = "C API for zenoh";
+    homepage = "https://github.com/eclipse-zenoh/zenoh-c";
+    license = with lib.licenses; [
+      asl20
+      epl20
+    ];
+    maintainers = with lib.maintainers; [ markuskowa ];
+  };
+}
@@ -0,0 +1,47 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  zenoh-c,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "zenoh-cpp";
+  version = "1.4.0"; # nixpkgs-update: no auto update
+
+  src = fetchFromGitHub {
+    owner = "eclipse-zenoh";
+    repo = "zenoh-cpp";
+    tag = version;
+    hash = "sha256-rznvif87UZbYzZB4yHG4R850qm6Z3beJ1NSG4wrf58M=";
+  };
+
+  cmakeFlags = [
+    "-DZENOHCXX_ZENOHC=ON"
+    "-DZENOHCXX_ZENOHPICO=OFF"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  propagatedBuildInputs = [
+    zenoh-c
+  ];
+
+  postInstall = ''
+    substituteInPlace $out/lib/pkgconfig/zenohcxx.pc \
+      --replace-fail "\''${prefix}/" ""
+  '';
+
+  meta = {
+    description = "C++ API for zenoh";
+    homepage = "https://github.com/eclipse-zenoh/zenoh-cpp";
+    license = with lib.licenses; [
+      asl20
+      epl20
+    ];
+    maintainers = with lib.maintainers; [ markuskowa ];
+  };
+}