e-imzo-manager: init at 0.1.1 (#433895)

maintainers/maintainer-list.nix

@@ -23290,6 +23290,12 @@
     githubId = 1588288;
     name = "Shahrukh Khan";
   };
+  shakhzodkudratov = {
+    email = "shakhzodkudratov@gmail.com";
+    github = "shakhzodkudratov";
+    githubId = 37299109;
+    name = "Shakhzod Kudratov";
+  };
   shamilton = {
     email = "sgn.hamilton@protonmail.com";
     github = "SCOTT-HAMILTON";

maintainers/team-list.nix

@@ -1256,6 +1256,7 @@ with lib.maintainers;
       orzklv
       bahrom04
       bemeritus
+      shakhzodkudratov
     ];
     scope = "Maintain Uzbek Linux state & community packages and modules.";
     shortName = "Uzinfocom Open Source";

pkgs/by-name/e-/e-imzo-manager/package.nix

@@ -0,0 +1,85 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  cargo,
+  desktop-file-utils,
+  gnome-desktop,
+  meson,
+  ninja,
+  pkg-config,
+  polkit,
+  rustc,
+  rustPlatform,
+  wrapGAppsHook4,
+  gdk-pixbuf,
+  glib,
+  adwaita-icon-theme,
+  gtk4,
+  libadwaita,
+  openssl,
+  nix-update-script,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "e-imzo-manager";
+  version = "0.1.1";
+
+  src = fetchFromGitHub {
+    owner = "xinux-org";
+    repo = "e-imzo";
+    tag = finalAttrs.version;
+    hash = "sha256-uDaqkz2VDvqTgi+k8EGGKjLkjoH93xXHQcgUc1NVo30=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) pname version src;
+    hash = "sha256-rulWG4L/uN6+JBk+SzC0y57Pdw5N0Q1dJlpXGVo+vbQ=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    cargo
+    rustPlatform.cargoSetupHook
+    rustc
+    desktop-file-utils
+    wrapGAppsHook4
+  ];
+
+  buildInputs = [
+    gdk-pixbuf
+    glib
+    gnome-desktop
+    adwaita-icon-theme
+    gtk4
+    libadwaita
+    openssl
+    rustPlatform.bindgenHook
+    polkit
+  ];
+
+  propagatedUserEnvPkgs = [ polkit ];
+
+  postInstall = ''
+    gappsWrapperArgs+=(
+      --suffix PATH : ${lib.makeBinPath finalAttrs.propagatedUserEnvPkgs}
+    )
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://github.com/xinux-org/e-imzo";
+    mainProgram = "E-IMZO-Manager";
+    description = "GTK application for managing E-IMZO keys";
+    license = with lib.licenses; [
+      asl20
+      mit
+    ];
+    platforms = lib.platforms.linux;
+    teams = [ lib.teams.uzinfocom ];
+  };
+})