python312Packages.pythonqwt: init at 0.12.7 (#327446)

pkgs/development/python-modules/guidata/default.nix

@@ -0,0 +1,96 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+
+  # build-system
+  setuptools,
+
+  # dependencies
+  numpy,
+  qtpy,
+  h5py,
+  requests,
+  tomli,
+
+  # tests
+  pytestCheckHook,
+  qt6,
+  pyqt6,
+
+  # passthru.tests
+  guidata,
+  pyside6,
+  qt5,
+  pyqt5,
+  pyside2,
+}:
+
+buildPythonPackage rec {
+  pname = "guidata";
+  version = "3.6.3";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "PlotPyStack";
+    repo = "guidata";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-KfeA6XNbzHZM4dyvAYlPOQIwWHwFT3Akj34zmgf8tb8=";
+  };
+
+  build-system = [
+    setuptools
+  ];
+
+  dependencies = [
+    numpy
+    qtpy
+    h5py
+    requests
+    tomli
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    # Not propagating this, to allow one to choose to choose a pyqt / pyside
+    # implementation.
+    pyqt6
+  ];
+
+  preCheck = ''
+    export QT_PLUGIN_PATH="${lib.getBin qt6.qtbase}/${qt6.qtbase.qtPluginPrefix}"
+    export QT_QPA_PLATFORM=offscreen
+  '';
+
+  pythonImportsCheck = [ "guidata" ];
+
+  passthru = {
+    tests = {
+      # Should be compatible with all of these Qt implementations
+      withPyQt6 = guidata.override {
+        pyqt6 = pyqt6;
+        qt6 = qt6;
+      };
+      withPySide6 = guidata.override {
+        pyqt6 = pyside6;
+        qt6 = qt6;
+      };
+      withPyQt5 = guidata.override {
+        pyqt6 = pyqt5;
+        qt6 = qt5;
+      };
+      withPySide2 = guidata.override {
+        pyqt6 = pyside2;
+        qt6 = qt5;
+      };
+    };
+  };
+
+  meta = {
+    description = "Python library generating graphical user interfaces for easy dataset editing and display";
+    homepage = "https://github.com/PlotPyStack/guidata";
+    changelog = "https://github.com/PlotPyStack/guidata/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ doronbehar ];
+  };
+}

pkgs/development/python-modules/plotpy/default.nix

@@ -0,0 +1,117 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+
+  # build-system
+  cython_0,
+  setuptools,
+
+  # dependencies
+  guidata,
+  numpy,
+  pillow,
+  pythonqwt,
+  scikit-image,
+  scipy,
+  tifffile,
+
+  # tests
+  pytestCheckHook,
+  qt6,
+  pyqt6,
+
+  # passthru.tests
+  plotpy,
+  pyside6,
+  qt5,
+  pyqt5,
+  pyside2,
+}:
+
+buildPythonPackage rec {
+  pname = "plotpy";
+  version = "2.6.3";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "PlotPyStack";
+    repo = "PlotPy";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-kMVq8X6XP18B5x35BTuC7Q5uFFwds1JxCaxlDuD/UfE=";
+  };
+
+  build-system = [
+    cython_0
+    setuptools
+  ];
+  # Both numpy versions are supported, see:
+  # https://github.com/PlotPyStack/PlotPy/blob/v2.6.2/pyproject.toml#L8-L9
+  postConfigure = ''
+    substituteInPlace pyproject.toml \
+      --replace-fail 'numpy >= 2.0.0' numpy
+  '';
+
+  dependencies = [
+    guidata
+    numpy
+    pillow
+    pythonqwt
+    scikit-image
+    scipy
+    tifffile
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    # Not propagating this, to allow one to choose to choose a pyqt / pyside
+    # implementation.
+    pyqt6
+  ];
+
+  preCheck = ''
+    export QT_PLUGIN_PATH="${lib.getBin qt6.qtbase}/${qt6.qtbase.qtPluginPrefix}"
+    export QT_QPA_PLATFORM=offscreen
+    # https://github.com/NixOS/nixpkgs/issues/255262
+    cd $out
+  '';
+
+  pythonImportsCheck = [
+    "plotpy"
+    "plotpy.tests"
+  ];
+
+  passthru = {
+    tests = {
+      # Upstream doesn't officially supports all of them, although they use
+      # qtpy, see: https://github.com/PlotPyStack/PlotPy/issues/20 . When this
+      # package was created, all worked besides withPySide2, with which there
+      # was a peculiar segmentation fault during the tests. In anycase, PySide2
+      # shouldn't be used for modern applications.
+      withPyQt6 = plotpy.override {
+        pyqt6 = pyqt6;
+        qt6 = qt6;
+      };
+      withPySide6 = plotpy.override {
+        pyqt6 = pyside6;
+        qt6 = qt6;
+      };
+      withPyQt5 = plotpy.override {
+        pyqt6 = pyqt5;
+        qt6 = qt5;
+      };
+      withPySide2 = plotpy.override {
+        pyqt6 = pyside2;
+        qt6 = qt5;
+      };
+    };
+  };
+
+  meta = {
+    description = "Curve and image plotting tools for Python/Qt applications";
+    homepage = "https://github.com/PlotPyStack/PlotPy";
+    changelog = "https://github.com/PlotPyStack/PlotPy/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ doronbehar ];
+  };
+}

pkgs/development/python-modules/pythonqwt/default.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+
+  # build-system
+  setuptools,
+
+  # dependencies
+  numpy,
+  qtpy,
+
+  # tests
+  pyqt6,
+  qt6,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "pythonqwt";
+  version = "0.12.7";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "PlotPyStack";
+    repo = "PythonQwt";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-Am7XYumq9PAOmT2ZTC+AAE4VM6/yNF11WLXoTFSbDh4=";
+  };
+
+  build-system = [
+    setuptools
+  ];
+
+  dependencies = [
+    qtpy
+    numpy
+  ];
+  nativeCheckInputs = [
+    pytestCheckHook
+    # Not propagating this, to allow one to choose to either choose a pyqt /
+    # pyside implementation
+    pyqt6
+  ];
+
+  preCheck = ''
+    export QT_PLUGIN_PATH="${lib.getBin qt6.qtbase}/${qt6.qtbase.qtPluginPrefix}"
+    export QT_QPA_PLATFORM=offscreen
+  '';
+
+  pythonImportsCheck = [ "qwt" ];
+
+  meta = {
+    description = "Qt plotting widgets for Python (pure Python reimplementation of Qwt C++ library)";
+    homepage = "https://github.com/PlotPyStack/PythonQwt";
+    changelog = "https://github.com/PlotPyStack/PythonQwt/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.lgpl21Only;
+    maintainers = with lib.maintainers; [ doronbehar ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -5510,6 +5510,8 @@ self: super: with self; {
 
   guidance = callPackage ../development/python-modules/guidance { };
 
+  guidata = callPackage ../development/python-modules/guidata { };
+
   gumath = callPackage ../development/python-modules/gumath { };
 
   gunicorn = callPackage ../development/python-modules/gunicorn { };
@@ -10509,6 +10511,8 @@ self: super: with self; {
 
   plotly = callPackage ../development/python-modules/plotly { };
 
+  plotpy = callPackage ../development/python-modules/plotpy { };
+
   plotnine = callPackage ../development/python-modules/plotnine { };
 
   pluggy = callPackage ../development/python-modules/pluggy { };
@@ -13371,6 +13375,8 @@ self: super: with self; {
 
   qmk-dotty-dict = callPackage ../development/python-modules/qmk-dotty-dict { };
 
+  pythonqwt = callPackage ../development/python-modules/pythonqwt { };
+
   r2pipe = callPackage ../development/python-modules/r2pipe { };
 
   rachiopy = callPackage ../development/python-modules/rachiopy { };