cloudquery: init at 6.36.1 (#531153)

pkgs/by-name/cl/cloudquery/package.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  nix-update-script,
+  installShellFiles,
+  versionCheckHook,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "cloudquery";
+  version = "6.36.1";
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "cloudquery";
+    repo = "cloudquery";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-D0gciTH5OwYXBPabOmn6bMHyWZwS6y5uAQIdNS+WugE=";
+  };
+
+  modRoot = "cli";
+
+  vendorHash = "sha256-gY/FQ71Nwk9i7QXgMmOVlJe9lEW9ViPZ3Eh1NusIizE=";
+
+  subPackages = [
+    "."
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/cloudquery/cloudquery/cli/v${lib.versions.major finalAttrs.version}/cmd.Version=${finalAttrs.version}"
+  ];
+
+  doInstallCheck = true;
+
+  nativeBuildInputs = [
+    installShellFiles
+    versionCheckHook
+  ];
+
+  postInstall = ''
+    mv $out/bin/cli $out/bin/cloudquery
+
+    installShellCompletion --cmd cloudquery \
+       --bash <($out/bin/cloudquery completion bash) \
+       --fish <($out/bin/cloudquery completion fish) \
+       --zsh <($out/bin/cloudquery completion zsh)
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Data pipelines for cloud config and security data";
+    homepage = "https://github.com/cloudquery/cloudquery";
+    changelog = "https://github.com/cloudquery/cloudquery/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.mpl20;
+    maintainers = with lib.maintainers; [ jlesquembre ];
+    mainProgram = "cloudquery";
+  };
+})