python3Packages.outlines: 0.0.46 -> 0.1.4 (#357313)

pkgs/development/python-modules/airportsdata/default.nix

@@ -0,0 +1,32 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+  pythonOlder,
+  setuptools,
+}:
+
+buildPythonPackage rec {
+  pname = "airportsdata";
+  version = "20241001";
+  pyproject = true;
+
+  disabled = pythonOlder "3.9";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-+gvRQ7T0vjVXy4kvoGEu8hD9kakr1yC02CId5Xak+gA=";
+  };
+
+  build-system = [ setuptools ];
+
+  pythonImportsCheck = [ "airportsdata" ];
+
+  meta = {
+    description = "Extensive database of location and timezone data for nearly every operational airport";
+    homepage = "https://github.com/mborsetti/airportsdata/";
+    changelog = "https://github.com/mborsetti/airportsdata/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ danieldk ];
+  };
+}

pkgs/development/python-modules/outlines-core/default.nix

@@ -0,0 +1,95 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+  pythonOlder,
+  cargo,
+  pkg-config,
+  rustPlatform,
+  rustc,
+  openssl,
+  setuptools-rust,
+  setuptools-scm,
+  interegular,
+  jsonschema,
+  datasets,
+  numpy,
+  pytestCheckHook,
+  pydantic,
+  scipy,
+  torch,
+  transformers,
+}:
+
+buildPythonPackage rec {
+  pname = "outlines-core";
+  version = "0.1.26";
+  pyproject = true;
+
+  disabled = pythonOlder "3.8";
+
+  src = fetchPypi {
+    inherit version;
+    pname = "outlines_core";
+    hash = "sha256-SBxDATQed8yPGDLWFnhK201GG0/sZYeOfA0sunFjoYk=";
+  };
+
+  cargoDeps = rustPlatform.importCargoLock {
+    lockFile = ./Cargo.lock;
+  };
+
+  postPatch = ''
+    cp --no-preserve=mode ${./Cargo.lock} Cargo.lock
+  '';
+
+  nativeBuildInputs = [
+    cargo
+    pkg-config
+    rustPlatform.cargoSetupHook
+    rustc
+  ];
+
+  buildInputs = [
+    openssl.dev
+  ];
+
+  build-system = [
+    setuptools-rust
+    setuptools-scm
+  ];
+
+  dependencies = [
+    interegular
+    jsonschema
+  ];
+
+  optional-dependencies = {
+    tests = [
+      datasets
+      numpy
+      pydantic
+      scipy
+      torch
+      transformers
+    ];
+  };
+
+  nativeCheckInputs = [ pytestCheckHook ] ++ lib.flatten (lib.attrValues optional-dependencies);
+
+  disabledTests = [
+    # Tests that need to download from Hugging Face Hub.
+    "test_complex_serialization"
+    "test_create_fsm_index_tokenizer"
+    "test_reduced_vocabulary_with_rare_tokens"
+  ];
+
+  pythonImportsCheck = [ "outlines_core" ];
+
+  meta = {
+    description = "Structured text generation (core)";
+    homepage = "https://github.com/outlines-dev/outlines-core";
+    changelog = "https://github.com/dottxt-ai/outlines-core/releases/tag/${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ danieldk ];
+  };
+}

pkgs/development/python-modules/outlines/default.nix

@@ -4,56 +4,60 @@
   fetchFromGitHub,
   setuptools,
   setuptools-scm,
+  airportsdata,
   interegular,
   cloudpickle,
   datasets,
   diskcache,
-  joblib,
+  jinja2,
   jsonschema,
-  pyairports,
+  numpy,
+  outlines-core,
   pycountry,
   pydantic,
   lark,
   nest-asyncio,
-  numba,
-  scipy,
+  referencing,
+  requests,
   torch,
   transformers,
 }:
 
 buildPythonPackage rec {
   pname = "outlines";
-  version = "0.0.46";
+  version = "0.1.13";
   pyproject = true;
 
   src = fetchFromGitHub {
     owner = "outlines-dev";
-    repo = pname;
+    repo = "outlines";
     tag = version;
-    hash = "sha256-6VH9BcMRVRf2xvLcK3GNA1pGgAOs95UOlFQ6KxHXwKo=";
+    hash = "sha256-HuJqLbBHyoyY5ChQQi+9ftvPjLuh63Guk2w6KSZxq6s=";
   };
 
-  nativeBuildInputs = [
+  build-system = [
     setuptools
     setuptools-scm
   ];
 
-  propagatedBuildInputs = [
+  dependencies = [
+    airportsdata
     interegular
     cloudpickle
     datasets
     diskcache
-    joblib
+    jinja2
     jsonschema
+    outlines-core
     pydantic
     lark
     nest-asyncio
-    numba
-    scipy
+    numpy
+    referencing
+    requests
     torch
     transformers
     pycountry
-    pyairports
   ];
 
   checkPhase = ''

pkgs/top-level/python-packages.nix

@@ -27,6 +27,8 @@ self: super: with self; {
 
   aafigure = callPackage ../development/python-modules/aafigure { };
 
+  airportsdata = callPackage ../development/python-modules/airportsdata { };
+
   aardwolf = callPackage ../development/python-modules/aardwolf { };
 
   abjad = callPackage ../development/python-modules/abjad { };
@@ -10317,6 +10319,8 @@ self: super: with self; {
 
   outlines = callPackage ../development/python-modules/outlines { };
 
+  outlines-core = callPackage ../development/python-modules/outlines-core { };
+
   overly = callPackage ../development/python-modules/overly { };
 
   overpy = callPackage ../development/python-modules/overpy { };