moonlight: init at 1.3.9

pkgs/by-name/mo/moonlight/package.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  stdenv,
+  nodejs,
+  pnpm_9,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "moonlight";
+  version = "1.3.9";
+
+  src = fetchFromGitHub {
+    owner = "moonlight-mod";
+    repo = "moonlight";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-WhPQ7JYfE8RBhDknBunKdW1VBxrklb3UGnMgk5LFVFA=";
+  };
+
+  nativeBuildInputs = [
+    nodejs
+    pnpm_9.configHook
+  ];
+
+  pnpmDeps = pnpm_9.fetchDeps {
+    inherit (finalAttrs) pname version src;
+
+    hash = "sha256-KZFHcW/OVjTDXZltxPYGuO+NWjuD5o6HE/E9JQZmrG8=";
+  };
+
+  buildPhase = ''
+    runHook preBuild
+
+    pnpm run build
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    cp -r dist $out
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    description = "Discord client modification, focused on enhancing user and developer experience";
+    longDescription = ''
+      Moonlight is a ***passion project***—yet another Discord client mod—focused on providing a decent user
+      and developer experience. Heavily inspired by hh3 (a private client mod) and the projects before it, namely EndPwn.
+      All core code is original or used with permission from their respective authors where not copyleft.
+    '';
+    homepage = "https://moonlight-mod.github.io";
+    changelog = "https://github.com/moonlight-mod/moonlight/blob/main/CHANGELOG.md";
+
+    license = licenses.lgpl3;
+    maintainers = with maintainers; [
+      ilys
+      donteatoreo
+    ];
+  };
+})