gitte: init at 0.6.1 (#524465)

maintainers/maintainer-list.nix

@@ -5150,6 +5150,13 @@
     githubId = 68239;
     name = "Christine Koppelt";
   };
+  ckruse = {
+    email = "cjk@defunct.ch";
+    github = "ckruse";
+    githubId = 175095;
+    name = "Christian Kruse";
+    keys = [ { fingerprint = "BC5D 9F4E F7FB 4382 6056  E834 B8E0 F342 A99A 9D73"; } ];
+  };
   clacke = {
     email = "claes.wallin@greatsinodevelopment.com";
     github = "clacke";

pkgs/by-name/gi/gitte/package.nix

@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  fetchFromCodeberg,
+  nix-update-script,
+  meson,
+  ninja,
+  pkg-config,
+  rustPlatform,
+  cargo,
+  rustc,
+  wrapGAppsHook4,
+  desktop-file-utils,
+  appstream,
+  gettext,
+  glib,
+  gtk4,
+  libadwaita,
+  openssl,
+  libgit2,
+  zlib,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gitte";
+  version = "0.6.1";
+
+  __structuredAttrs = true;
+
+  src = fetchFromCodeberg {
+    owner = "ckruse";
+    repo = "Gitte";
+    tag = finalAttrs.version;
+    hash = "sha256-ieW/oOFdyJWVR/7B62Rzcyii+/zDj/Xp6KCrVOf6mpA=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) pname version src;
+    hash = "sha256-VhcJepTeEjA/ZogqR82Whlyz4NRuI5MLB2HqNjGe8zQ=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    rustPlatform.cargoSetupHook
+    cargo
+    rustc
+    wrapGAppsHook4
+    desktop-file-utils
+    appstream
+    gettext
+    glib
+  ];
+
+  buildInputs = [
+    gtk4
+    libadwaita
+    openssl
+    libgit2
+    zlib
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://codeberg.org/ckruse/Gitte";
+    mainProgram = "gitte";
+    description = "GTK4/libadwaita Git client";
+    license = with lib.licenses; [ agpl3Plus ];
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [
+      ckruse
+      orzklv
+    ];
+  };
+})