python312Packages.ipydatagrid: init at 1.4.0

pkgs/development/python-modules/ipydatagrid/default.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  pytestCheckHook,
+
+  hatchling,
+  hatch-jupyter-builder,
+  jupyterlab,
+  bqplot,
+  ipywidgets,
+  pandas,
+  py2vega,
+  yarn-berry_3,
+}:
+
+let
+  yarn-berry = yarn-berry_3;
+in
+
+buildPythonPackage rec {
+  pname = "ipydatagrid";
+  version = "1.4.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "jupyter-widgets";
+    repo = "ipydatagrid";
+    tag = version;
+    hash = "sha256-6jaIYgLbNXIYzM+mZIVMZ1CXOpcbVK5k9nzGjq5UdLI=";
+  };
+
+  build-system = [
+    hatchling
+    hatch-jupyter-builder
+    jupyterlab
+  ];
+
+  nativeBuildInputs = [
+    yarn-berry.yarnBerryConfigHook
+    yarn-berry
+  ];
+
+  dependencies = [
+    bqplot
+    ipywidgets
+    pandas
+    py2vega
+  ];
+
+  offlineCache = yarn-berry.fetchYarnBerryDeps {
+    inherit src;
+    hash = "sha256-5KZl9mK6xNvy2XdWieH20hEZJ+h/KzvjOfpo78FlWpg=";
+  };
+
+  preConfigure = ''
+    substituteInPlace pyproject.toml package.json \
+      --replace-fail 'jlpm' 'yarn'
+  '';
+
+  nativeCheckInputs = [
+    pytestCheckHook
+  ];
+
+  meta = {
+    description = "Fast Datagrid widget for the Jupyter Notebook and JupyterLab";
+    homepage = "https://github.com/jupyter-widgets/ipydatagrid";
+    changelog = "https://github.com/jupyter-widgets/ipydatagrid/releases/tag/${version}";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ flokli ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -6811,6 +6811,8 @@ self: super: with self; {
 
   ipycanvas = callPackage ../development/python-modules/ipycanvas { };
 
+  ipydatagrid = callPackage ../development/python-modules/ipydatagrid { };
+
   ipydatawidgets = callPackage ../development/python-modules/ipydatawidgets { };
 
   ipykernel = callPackage ../development/python-modules/ipykernel { };