Merge pull request #325568 from atorres1985-contrib/sdl2-image-master

SDL2_Image: rework and modernize

pkgs/by-name/sd/SDL2_image/package.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  SDL2,
+  darwin,
+  fetchurl,
+  giflib,
+  libXpm,
+  libjpeg,
+  libpng,
+  libtiff,
+  libwebp,
+  pkg-config,
+  stdenv,
+  zlib,
+  # Boolean flags
+  ## Darwin headless will hang when trying to run the SDL test program
+  enableSdltest ? (!stdenv.isDarwin),
+}:
+
+let
+  inherit (darwin.apple_sdk.frameworks) Foundation;
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "SDL2_image";
+  version = "2.8.2";
+
+  src = fetchurl {
+    url = "https://www.libsdl.org/projects/SDL_image/release/SDL2_image-${finalAttrs.version}.tar.gz";
+    hash = "sha256-j0hrv7z4Rk3VjJ5dkzlKsCVc5otRxalmqRgkSCCnbdw=";
+  };
+
+  nativeBuildInputs = [
+    SDL2
+    pkg-config
+  ];
+
+  buildInputs = [
+    SDL2
+    giflib
+    libXpm
+    libjpeg
+    libpng
+    libtiff
+    libwebp
+    zlib
+  ] ++ lib.optionals stdenv.isDarwin [ Foundation ];
+
+  configureFlags = [
+    # Disable dynamically loaded dependencies
+    (lib.enableFeature false "jpg-shared")
+    (lib.enableFeature false "png-shared")
+    (lib.enableFeature false "tif-shared")
+    (lib.enableFeature false "webp-shared")
+    (lib.enableFeature enableSdltest "sdltest")
+  ] ++ lib.optionals stdenv.isDarwin [
+    # Don't use native macOS frameworks
+    # Caution: do not set this as (!stdenv.isDarwin) since it would be true
+    # outside Darwin - and ImageIO does not exist outisde Darwin
+    (lib.enableFeature false "imageio")
+  ];
+
+  strictDeps = true;
+
+  enableParallelBuilding = true;
+
+  meta = {
+    description = "SDL image library";
+    homepage = "https://github.com/libsdl-org/SDL_image";
+    license = lib.licenses.zlib;
+    maintainers = lib.teams.sdl.members ++ (with lib.maintainers; [ ]);
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/sd/SDL2_image_2_0/package.nix

@@ -0,0 +1,14 @@
+# Dependency of pygame, toppler
+{
+  lib,
+  SDL2_image,
+  fetchurl,
+}:
+
+SDL2_image.overrideAttrs (oldAttrs: {
+  version = "2.0.5";
+  src = fetchurl {
+    inherit (oldAttrs.src) url;
+    hash = "sha256-vdX24CZoL31+G+C2BRsgnaL0AqLdi9HEvZwlrSYxCNA";
+  };
+})

pkgs/by-name/sd/SDL2_image_2_6/package.nix

@@ -0,0 +1,15 @@
+# Dependency for hedgewars:
+# https://github.com/NixOS/nixpkgs/pull/274185#issuecomment-1856764786
+{
+  lib,
+  SDL2_image,
+  fetchurl,
+}:
+
+SDL2_image.overrideAttrs (oldAttrs: {
+  version = "2.6.3";
+  src = fetchurl {
+    inherit (oldAttrs.src) url;
+    hash = "sha256-kxyb5b8dfI+um33BV4KLfu6HTiPH8ktEun7/a0g2MSw=";
+  };
+})

pkgs/development/libraries/SDL2_image/default.nix

@@ -1,42 +0,0 @@
-{ lib, stdenv, fetchurl
-, pkg-config
-, SDL2, libpng, libjpeg, libtiff, giflib, libwebp, libXpm, zlib, Foundation
-}:
-
-stdenv.mkDerivation (finalAttrs: {
-  pname = "SDL2_image";
-  version = "2.8.2";
-
-  src = fetchurl {
-    url = "https://www.libsdl.org/projects/SDL_image/release/SDL2_image-${finalAttrs.version}.tar.gz";
-    hash = "sha256-j0hrv7z4Rk3VjJ5dkzlKsCVc5otRxalmqRgkSCCnbdw=";
-  };
-
-  nativeBuildInputs = [ pkg-config ];
-
-  buildInputs = [ SDL2 libpng libjpeg libtiff giflib libwebp libXpm zlib ]
-    ++ lib.optional stdenv.isDarwin Foundation;
-
-  configureFlags = [
-    # Disable dynamically loaded dependencies
-    "--disable-jpg-shared"
-    "--disable-png-shared"
-    "--disable-tif-shared"
-    "--disable-webp-shared"
-  ] ++ lib.optionals stdenv.isDarwin [
-    # Darwin headless will hang when trying to run the SDL test program
-    "--disable-sdltest"
-    # Don't use native macOS frameworks
-    "--disable-imageio"
-  ];
-
-  enableParallelBuilding = true;
-
-  meta = with lib; {
-    description = "SDL image library";
-    homepage = "http://www.libsdl.org/projects/SDL_image/";
-    platforms = platforms.unix;
-    license = licenses.zlib;
-    maintainers = with maintainers; [ cpages ];
-  };
-})

pkgs/top-level/all-packages.nix

@@ -23972,27 +23972,6 @@ with pkgs;
     inherit (darwin.apple_sdk.frameworks) AudioUnit Cocoa CoreAudio CoreServices ForceFeedback OpenGL;
   };
 
-  SDL2_image = callPackage ../development/libraries/SDL2_image {
-    inherit (darwin.apple_sdk.frameworks) Foundation;
-  };
-  # Pinned for pygame, toppler
-  SDL2_image_2_0 = SDL2_image.overrideAttrs (oldAttrs: {
-    version = "2.0.5";
-    src = fetchurl {
-      inherit (oldAttrs.src) url;
-      hash = "sha256-vdX24CZoL31+G+C2BRsgnaL0AqLdi9HEvZwlrSYxCNA";
-    };
-  });
-  # Pinned for hedgewars:
-  #   https://github.com/NixOS/nixpkgs/pull/274185#issuecomment-1856764786
-  SDL2_image_2_6 = SDL2_image.overrideAttrs (oldAttrs: {
-    version = "2.6.3";
-    src = fetchurl {
-      inherit (oldAttrs.src) url;
-      hash = "sha256-kxyb5b8dfI+um33BV4KLfu6HTiPH8ktEun7/a0g2MSw=";
-    };
-  });
-
   sdrplay = callPackage ../applications/radio/sdrplay { };
 
   sdr-j-fm = libsForQt5.callPackage ../applications/radio/sdr-j-fm { };