clapper-unwrapped: separated from clapper; clapper-enhancers: init at 0.8.2 (#399376)

pkgs/by-name/cl/clapper-enhancers/package.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  gobject-introspection,
+  libpeas2,
+  json-glib,
+  libsoup_3,
+  glib,
+  clapper-unwrapped,
+  gst_all_1,
+  python3Packages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "clapper-enhancers";
+  version = "0.8.2";
+
+  src = fetchFromGitHub {
+    owner = "Rafostar";
+    repo = "clapper-enhancers";
+    tag = finalAttrs.version;
+    hash = "sha256-CUfTz+YvliJXiv/nsdrpDVFSblqoSW7js8vAtJ9u5vM=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    gobject-introspection
+    python3Packages.python
+    python3Packages.wrapPython
+  ];
+
+  buildInputs = [
+    libpeas2
+    json-glib
+    libsoup_3
+    glib
+    clapper-unwrapped
+    gst_all_1.gstreamer
+    gst_all_1.gst-plugins-base
+    gst_all_1.gst-plugins-good
+    gst_all_1.gst-plugins-bad
+    gst_all_1.gst-plugins-ugly
+  ];
+
+  pythonPath = with python3Packages; [
+    yt-dlp
+  ];
+
+  postFixup = ''
+    buildPythonPath "$out $pythonPath"
+    for yt_plugin in $out/lib/clapper-enhancers/plugins/yt-dlp/*.py; do
+      patchPythonScript $yt_plugin
+    done
+  '';
+
+  mesonFlags = [ "-Denhancersdir=${placeholder "out"}/${finalAttrs.passthru.pluginPath}" ];
+
+  passthru.pluginPath = "lib/clapper-enhancers/plugins";
+
+  meta = {
+    description = "Plugins enhancing Clapper library capabilities";
+    homepage = "https://github.com/Rafostar/clapper-enhancers";
+    license = lib.licenses.lgpl21Only;
+    inherit (clapper-unwrapped.meta) maintainers platforms;
+  };
+})

pkgs/by-name/cl/clapper-unwrapped/package.nix

@@ -0,0 +1,86 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  gobject-introspection,
+  pkg-config,
+  ninja,
+  desktop-file-utils,
+  shared-mime-info,
+  meson,
+  gtk4,
+  gst_all_1,
+  libGL,
+  libadwaita,
+  libsoup_3,
+  vala,
+  cmake,
+  libmicrodns,
+  glib-networking,
+  libpeas2,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "clapper-unwrapped";
+  version = "0.8.0";
+
+  outputs = [
+    "out"
+    "lib"
+    "dev"
+  ];
+
+  src = fetchFromGitHub {
+    owner = "Rafostar";
+    repo = "clapper";
+    tag = finalAttrs.version;
+    hash = "sha256-Yb2fWsdd8jhxkGWKanLn7CAuF4MjyQ27XTrO8ja3hfs=";
+  };
+
+  nativeBuildInputs = [
+    gobject-introspection
+    meson
+    cmake
+    ninja
+    pkg-config
+    desktop-file-utils # for update-desktop-database
+    shared-mime-info # for update-mime-database
+    vala
+  ];
+
+  buildInputs = [
+    gst_all_1.gstreamer
+    gst_all_1.gst-plugins-base
+    gst_all_1.gst-plugins-good
+    gst_all_1.gst-plugins-bad
+    gst_all_1.gst-plugins-ugly
+    glib-networking # for TLS support
+    gtk4
+    libGL
+    libadwaita
+    libsoup_3
+    libmicrodns
+    libpeas2
+  ];
+
+  postPatch = ''
+    patchShebangs --build build-aux/meson/postinstall.py
+  '';
+
+  preFixup = ''
+    mkdir -p $out/share/gsettings-schemas
+    cp -r $lib/share/gsettings-schemas/clapper-unwrapped-$version $out/share/gsettings-schemas/clapper-$version
+  '';
+
+  meta = {
+    description = "GNOME media player built using GTK4 toolkit and powered by GStreamer with OpenGL rendering";
+    longDescription = ''
+      Clapper is a GNOME media player built using the GTK4 toolkit.
+      The media player is using GStreamer as a media backend.
+    '';
+    homepage = "https://github.com/Rafostar/clapper";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ aleksana ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/cl/clapper/package.nix

@@ -1,88 +1,41 @@
 {
-  lib,
-  stdenv,
-  fetchFromGitHub,
-  gobject-introspection,
-  pkg-config,
-  ninja,
-  desktop-file-utils,
-  makeWrapper,
-  shared-mime-info,
+  stdenvNoCC,
+  clapper-unwrapped,
   wrapGAppsHook4,
-  meson,
-  gtk4,
-  gst_all_1,
-  libGL,
-  libadwaita,
-  libsoup_3,
-  vala,
-  cmake,
-  libmicrodns,
-  gtuber,
-  glib-networking,
-  libpeas2,
+  gobject-introspection,
+  xorg,
+  clapper-enhancers,
 }:
 
-stdenv.mkDerivation (finalAttrs: {
+stdenvNoCC.mkDerivation {
   pname = "clapper";
-  version = "0.8.0";
+  inherit (clapper-unwrapped) version meta;
 
-  src = fetchFromGitHub {
-    owner = "Rafostar";
-    repo = "clapper";
-    tag = finalAttrs.version;
-    hash = "sha256-Yb2fWsdd8jhxkGWKanLn7CAuF4MjyQ27XTrO8ja3hfs=";
-  };
+  src = clapper-unwrapped;
+
+  dontConfigure = true;
+  dontBuild = true;
 
   nativeBuildInputs = [
+    wrapGAppsHook4
     gobject-introspection
-    meson
-    cmake
-    ninja
-    makeWrapper
-    pkg-config
-    wrapGAppsHook4 # for gsettings
-    desktop-file-utils # for update-desktop-database
-    shared-mime-info # for update-mime-database
-    vala
+    xorg.lndir
   ];
 
-  buildInputs = [
-    gst_all_1.gstreamer
-    gst_all_1.gst-plugins-base
-    gst_all_1.gst-plugins-good
-    gst_all_1.gst-plugins-bad
-    gst_all_1.gst-plugins-ugly
-    gtuber
-    glib-networking # for TLS support
-    gtk4
-    libGL
-    libadwaita
-    libsoup_3
-    libmicrodns
-    libpeas2
-  ];
+  buildInputs = [ clapper-unwrapped ] ++ clapper-unwrapped.buildInputs;
 
-  postPatch = ''
-    patchShebangs --build build-aux/meson/postinstall.py
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+    lndir $src $out
+
+    runHook postInstall
   '';
 
-  # The package uses "clappersink" provided by itself
   preFixup = ''
     gappsWrapperArgs+=(
-      --prefix GST_PLUGIN_SYSTEM_PATH_1_0 : $out/lib/gstreamer-1.0
+      --set-default CLAPPER_ENHANCERS_PATH "${clapper-enhancers}/${clapper-enhancers.passthru.pluginPath}"
     )
   '';
-
-  meta = {
-    description = "GNOME media player built using GTK4 toolkit and powered by GStreamer with OpenGL rendering";
-    longDescription = ''
-      Clapper is a GNOME media player built using the GTK4 toolkit.
-      The media player is using GStreamer as a media backend.
-    '';
-    homepage = "https://github.com/Rafostar/clapper";
-    license = lib.licenses.gpl3Plus;
-    maintainers = with lib.maintainers; [ aleksana ];
-    platforms = lib.platforms.linux;
-  };
-})
+}

pkgs/by-name/ne/newsflash/package.nix

@@ -12,7 +12,7 @@
   rustc,
   wrapGAppsHook4,
   gdk-pixbuf,
-  clapper,
+  clapper-unwrapped,
   gtk4,
   libadwaita,
   libxml2,
@@ -66,7 +66,7 @@ stdenv.mkDerivation (finalAttrs: {
 
   buildInputs =
     [
-      clapper
+      clapper-unwrapped
       gtk4
       libadwaita
       libxml2

pkgs/by-name/pi/pipeline/package.nix

@@ -17,7 +17,7 @@
   desktop-file-utils,
   blueprint-compiler,
   sqlite,
-  clapper,
+  clapper-unwrapped,
   gettext,
   gst_all_1,
   gtuber,
@@ -63,7 +63,7 @@ stdenv.mkDerivation (finalAttrs: {
     libadwaita
     openssl
     sqlite
-    clapper
+    clapper-unwrapped
 
     gst_all_1.gstreamer
     gst_all_1.gst-libav

pkgs/by-name/te/televido/package.nix

@@ -14,7 +14,7 @@
   desktop-file-utils,
   openssl,
   gst_all_1,
-  clapper,
+  clapper-unwrapped,
 }:
 
 stdenv.mkDerivation rec {
@@ -49,7 +49,7 @@ stdenv.mkDerivation rec {
   buildInputs = [
     libadwaita
     desktop-file-utils
-    clapper
+    clapper-unwrapped
     gst_all_1.gstreamer
     gst_all_1.gst-plugins-base
     gst_all_1.gst-libav

pkgs/by-name/tu/tuba/package.nix

@@ -27,7 +27,7 @@
   webp-pixbuf-loader,
   icu,
   gst_all_1,
-  clapper,
+  clapper-unwrapped,
   # clapper support is still experimental and has bugs.
   # See https://github.com/GeopJr/Tuba/pull/931
   clapperSupport ? false,
@@ -80,7 +80,7 @@ stdenv.mkDerivation rec {
       gst-plugins-bad
     ])
     ++ lib.optionals clapperSupport [
-      clapper
+      clapper-unwrapped
     ];
 
   mesonFlags = [