icm: init at 0.10.49 (#519959)

2026-05-15 17:35:46 +00:00
parent 9a2a13a6fa 1d5f264884
commit 99f41fbbf5
1 changed files with 68 additions and 0 deletions
@@ -0,0 +1,68 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  openssl,
+  nix-update-script,
+  onnxruntime,
+  versionCheckHook,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "icm";
+  version = "0.10.49";
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "rtk-ai";
+    repo = "icm";
+    tag = "icm-v${finalAttrs.version}";
+    hash = "sha256-GB2SH/Y2l4AkxoFqJfWcsGmWK4uOayCs1FSxBuXShwc=";
+  };
+
+  cargoHash = "sha256-U0mHWzRI6BDVC4LRpwWz/QbCeT0fEPxKoY5+1DrI048=";
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    openssl
+    onnxruntime
+  ];
+
+  # Build the HTTP dashboard
+  buildFeatures = [ "web" ];
+
+  env = {
+    # Use system OpenSSL instead of vendoring it
+    OPENSSL_NO_VENDOR = "1";
+    # Point ort (ONNX Runtime bindings) at the system library
+    ORT_STRATEGY = "system";
+    ORT_LIB_LOCATION = "${lib.getLib onnxruntime}/lib";
+  };
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+  doInstallCheck = true;
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [
+      "--version-regex"
+      "^icm-(.*)"
+    ];
+  };
+
+  meta = {
+    description = "Permanent memory system for AI agents with MCP integration";
+    homepage = "https://github.com/rtk-ai/icm";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ jpds ];
+    mainProgram = "icm";
+    platforms = lib.platforms.unix;
+    broken = stdenv.hostPlatform.isDarwin;
+  };
+})