libsForQt5.soqt: 2020-12-05-unstable -> 1.6.4; migrate to qt6 and pkgs/by-name (#447375)

pkgs/by-name/so/soqt/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  coin3d,
+  qt6,
+  testers,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "soqt";
+  version = "1.6.4";
+
+  src = fetchFromGitHub {
+    owner = "coin3d";
+    repo = "soqt";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-H904mFfrELjB6ZVhypaKJd+pu5y+aVV4foryrsN7IqE=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  propagatedBuildInputs = [
+    coin3d
+    qt6.qtbase
+  ];
+
+  dontWrapQtApps = true;
+
+  passthru = {
+    tests = {
+      cmake-config = testers.hasCmakeConfigModules {
+        moduleNames = [ "soqt" ];
+        package = finalAttrs.finalPackage;
+        nativeBuildInputs = [ qt6.wrapQtAppsHook ];
+      };
+    };
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    homepage = "https://github.com/coin3d/soqt";
+    license = lib.licenses.bsd3;
+    description = "Glue between Coin high-level 3D visualization library and Qt";
+    maintainers = with lib.maintainers; [ ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/development/libraries/soqt/default.nix

@@ -1,43 +0,0 @@
-{
-  fetchFromGitHub,
-  lib,
-  stdenv,
-  coin3d,
-  qtbase,
-  cmake,
-  pkg-config,
-}:
-
-stdenv.mkDerivation {
-  pname = "soqt";
-  version = "2020-12-05-unstable";
-
-  src = fetchFromGitHub {
-    owner = "coin3d";
-    repo = "soqt";
-    # rev = "SoQt-${version}";
-    rev = "fb8f655632bb9c9c60e0ff9fa69a5ba22d3ff99d";
-    hash = "sha256-YoBq8P3Tag2Sepqxf/qIcJDBhH/gladBmDUj78aacZs=";
-    fetchSubmodules = true;
-  };
-
-  buildInputs = [
-    coin3d
-    qtbase
-  ];
-
-  nativeBuildInputs = [
-    cmake
-    pkg-config
-  ];
-
-  dontWrapQtApps = true;
-
-  meta = with lib; {
-    homepage = "https://github.com/coin3d/soqt";
-    license = licenses.bsd3;
-    description = "Glue between Coin high-level 3D visualization library and Qt";
-    maintainers = with maintainers; [ ];
-    platforms = platforms.linux;
-  };
-}

pkgs/development/python-modules/pivy/default.nix

@@ -2,17 +2,19 @@
   lib,
   buildPythonPackage,
   fetchFromGitHub,
-  setuptools,
-  pkgs,
-  qtbase,
-  qmake,
+  python,
+  pythonRecompileBytecodeHook,
+  swig,
+  cmake,
+  coin3d,
   soqt,
+  libGLU,
 }:
 
 buildPythonPackage rec {
   pname = "pivy";
   version = "0.6.10";
-  pyproject = true;
+  format = "other";
 
   src = fetchFromGitHub {
     owner = "coin3d";
@@ -21,54 +23,31 @@ buildPythonPackage rec {
     hash = "sha256-DRA4NTAHg2iB/D1CU9pJEpsZwX9GW3X5gpxbIwP54Ko=";
   };
 
-  build-system = [ setuptools ];
-
-  dontUseCmakeConfigure = true;
-
-  nativeBuildInputs = with pkgs; [
+  nativeBuildInputs = [
     swig
-    qmake
     cmake
+    pythonRecompileBytecodeHook
   ];
 
-  buildInputs =
-    with pkgs;
-    with xorg;
-    [
-      coin3d
-      soqt
-      qtbase
-      libGLU
-      libGL
-      libXi
-      libXext
-      libSM
-      libICE
-      libX11
-    ];
+  buildInputs = [
+    coin3d
+    soqt
+    libGLU # dummy buildInput that provides missing header <GL/glu.h>
+  ];
 
-  env.NIX_CFLAGS_COMPILE = toString [
-    "-I${qtbase.dev}/include/QtCore"
-    "-I${qtbase.dev}/include/QtGui"
-    "-I${qtbase.dev}/include/QtOpenGL"
-    "-I${qtbase.dev}/include/QtWidgets"
+  cmakeFlags = [
+    (lib.cmakeBool "PIVY_USE_QT6" true)
+    (lib.cmakeFeature "PIVY_Python_SITEARCH" "${placeholder "out"}/${python.sitePackages}")
   ];
 
-  dontUseQmakeConfigure = true;
   dontWrapQtApps = true;
-  doCheck = false;
-
-  postPatch = ''
-    substituteInPlace distutils_cmake/CMakeLists.txt --replace \$'{SoQt_INCLUDE_DIRS}' \
-      \$'{Coin_INCLUDE_DIR}'\;\$'{SoQt_INCLUDE_DIRS}'
-  '';
 
   pythonImportsCheck = [ "pivy" ];
 
-  meta = with lib; {
+  meta = {
     homepage = "https://github.com/coin3d/pivy/";
     description = "Python binding for Coin";
-    license = licenses.bsd0;
-    maintainers = with maintainers; [ ];
+    license = lib.licenses.bsd0;
+    maintainers = with lib.maintainers; [ ];
   };
 }

pkgs/top-level/python-packages.nix

@@ -11858,10 +11858,7 @@ self: super: with self; {
 
   piqp = callPackage ../development/python-modules/piqp { };
 
-  pivy = callPackage ../development/python-modules/pivy {
-    inherit (pkgs.qt5) qtbase qmake;
-    inherit (pkgs.libsForQt5) soqt;
-  };
+  pivy = callPackage ../development/python-modules/pivy { };
 
   pixcat = callPackage ../development/python-modules/pixcat { };
 

pkgs/top-level/qt5-packages.nix

@@ -215,8 +215,6 @@ makeScopeWithSplicing' {
           callPackage ../development/libraries/sailfish-access-control-plugin
             { };
 
-        soqt = callPackage ../development/libraries/soqt { };
-
         telepathy = callPackage ../development/libraries/telepathy/qt { };
 
         qtwebkit-plugins = callPackage ../development/libraries/qtwebkit-plugins { };