nodePackages.keyoxide: migrate from nodePackages

pkgs/by-name/ke/keyoxide-cli/package.nix

@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitea,
+  fetchYarnDeps,
+  yarnConfigHook,
+  yarnBuildHook,
+  yarnInstallHook,
+  nodejs,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "keyoxide-cli";
+  version = "0.4.4";
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "keyoxide";
+    repo = "keyoxide-cli";
+    tag = finalAttrs.version;
+    hash = "sha256-lQEvtqFq3OBlXdYdrhMsAns4kimR2RfRx3VFNy4nEu8=";
+  };
+
+  yarnOfflineCache = fetchYarnDeps {
+    inherit (finalAttrs) src;
+    hash = "sha256-UxP5NkmA3MsrXhoa+JviDdW19HKE6Xpj1dkN7h0ggck=";
+  };
+
+  yarnBuildScript = "prettier";
+  yarnBuildFlags = "src/commands.js";
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    yarnBuildHook
+    yarnInstallHook
+    # Needed for executing package.json scripts
+    nodejs
+  ];
+
+  meta = {
+    changelog = "https://codeberg.org/keyoxide/keyoxide-cli/releases/tag/${finalAttrs.version}";
+    description = "Command-line interface to locally verify decentralized identities";
+    homepage = "https://codeberg.org/keyoxide/keyoxide-cli";
+    license = lib.licenses.agpl3Plus;
+    maintainers = [ lib.maintainers.pyrox0 ];
+    mainProgram = "keyoxide";
+  };
+})

pkgs/development/node-packages/aliases.nix

@@ -146,6 +146,7 @@ mapAliases {
   inherit (pkgs) javascript-typescript-langserver; # added 2023-08-19
   inherit (pkgs) kaput-cli; # added 2024-12-03
   karma = pkgs.karma-runner; # added 2023-07-29
+  keyoxide = pkgs.keyoxide-cli; # Added 2025-10-20
   leetcode-cli = self.vsc-leetcode-cli; # added 2023-08-31
   inherit (pkgs) lerna; # added 2025-02-12
   less = pkgs.lessc; # added 2024-06-15

pkgs/development/node-packages/node-packages.json

@@ -96,7 +96,6 @@
 , "jsonlint"
 , "jsonplaceholder"
 , "katex"
-, "keyoxide"
 , "lcov-result-merger"
 , "live-server"
 , "livedown"

pkgs/development/node-packages/overrides.nix

@@ -111,15 +111,6 @@ final: prev: {
     '';
   };
 
-  keyoxide = prev.keyoxide.override {
-    nativeBuildInputs = [ pkgs.pkg-config ];
-    buildInputs = with pkgs; [
-      pixman
-      cairo
-      pango
-    ];
-  };
-
   makam = prev.makam.override {
     nativeBuildInputs = [ pkgs.buildPackages.makeWrapper ];
     postFixup = ''