python3Packages.pytest_9_0: init at 9.0.3

For packages lagging behind on updating pytest.
2026-07-15 03:12:26 +02:00
parent 8be19173ac
commit 913358ad67
2 changed files with 108 additions and 0 deletions
@@ -0,0 +1,104 @@
+{
+  lib,
+  buildPythonPackage,
+  callPackage,
+  fetchPypi,
+  writeText,
+
+  # build-system
+  setuptools,
+  setuptools-scm,
+
+  # dependencies
+  attrs,
+  iniconfig,
+  packaging,
+  pluggy,
+
+  # optional-dependencies
+  argcomplete,
+  hypothesis,
+  mock,
+  pygments,
+  requests,
+  xmlschema,
+}:
+
+buildPythonPackage rec {
+  pname = "pytest";
+  version = "9.0.3";
+  pyproject = true;
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-uGraUIr4HRnt6yE8aBsdSCRsGpHTBMbIGkJ2dMF+uRw=";
+  };
+
+  outputs = [
+    "out"
+    "testout"
+  ];
+
+  build-system = [
+    setuptools
+    setuptools-scm
+  ];
+
+  dependencies = [
+    iniconfig
+    packaging
+    pluggy
+    pygments
+  ];
+
+  optional-dependencies = {
+    testing = [
+      argcomplete
+      attrs
+      hypothesis
+      mock
+      requests
+      setuptools
+      xmlschema
+    ];
+  };
+
+  postInstall = ''
+    mkdir $testout
+    cp -R testing $testout/testing
+  '';
+
+  doCheck = false;
+  passthru.tests.pytest = callPackage ./tests.nix { };
+
+  # Remove .pytest_cache when using py.test in a Nix build
+  setupHook = writeText "pytest-hook" ''
+    pytestcachePhase() {
+        find $out -name .pytest_cache -type d -exec rm -rf {} +
+    }
+    appendToVar preDistPhases pytestcachePhase
+
+    # pytest generates it's own bytecode files to improve assertion messages.
+    # These files similar to cpython's bytecode files but are never laoded
+    # by python interpreter directly. We remove them for a few reasons:
+    # - files are non-deterministic: https://github.com/NixOS/nixpkgs/issues/139292
+    #   (file headers are generatedt by pytest directly and contain timestamps)
+    # - files are not needed after tests are finished
+    pytestRemoveBytecodePhase () {
+        # suffix is defined at:
+        #    https://github.com/pytest-dev/pytest/blob/7.2.1/src/_pytest/assertion/rewrite.py#L51-L53
+        find $out -name "*-pytest-*.py[co]" -delete
+    }
+    appendToVar preDistPhases pytestRemoveBytecodePhase
+  '';
+
+  pythonImportsCheck = [ "pytest" ];
+
+  meta = {
+    description = "Framework for writing tests";
+    homepage = "https://docs.pytest.org";
+    changelog = "https://github.com/pytest-dev/pytest/releases/tag/${version}";
+    teams = [ lib.teams.python ];
+    license = lib.licenses.mit;
+  };
+}
@@ -16326,10 +16326,14 @@ self: super: with self; {

  pytest8_3CheckHook = pytestCheckHook.override { pytest = pytest_8_3; };

+  pytest9_0CheckHook = pytestCheckHook.override { pytest = pytest_9_0; };
+
  pytest_7 = callPackage ../development/python-modules/pytest/7.nix { };

  pytest_8_3 = callPackage ../development/python-modules/pytest/8_3.nix { };

+  pytest_9_0 = callPackage ../development/python-modules/pytest/9_0.nix { };
+
  pytestcache = callPackage ../development/python-modules/pytestcache { };

  pythinkingcleaner = callPackage ../development/python-modules/pythinkingcleaner { };