livecaptions: init at 0.4.0

Signed-off-by: Sefa Eyeoglu <contact@scrumplex.net>

pkgs/applications/misc/livecaptions/default.nix

@@ -0,0 +1,76 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchurl,
+  meson,
+  ninja,
+  pkg-config,
+  cmake,
+  desktop-file-utils,
+  wrapGAppsHook4,
+  onnxruntime,
+  libadwaita,
+  libpulseaudio,
+  xorg,
+}: let
+  aprilAsr = fetchFromGitHub {
+    name = "april-asr";
+    owner = "abb128";
+    repo = "april-asr";
+    rev = "c2f138c674cad58e2708ecaddc95cc72e7f85549";
+    sha256 = "hZe2iss3BGdzeTM5FCp9wp6LaDOjtGJrZS5vB5F6uLg=";
+  };
+
+  aprilModel = fetchurl {
+    name = "aprilv0_en-us.april";
+    url = "https://april.sapples.net/aprilv0_en-us.april";
+    sha256 = "9aMPiI55d2mxt94UPAXSySoXAsJjtbcdYv0gKM7eVic=";
+  };
+in
+  stdenv.mkDerivation rec {
+    pname = "livecaptions";
+    version = "0.4.0";
+
+    src = fetchFromGitHub {
+      owner = "abb128";
+      repo = "LiveCaptions";
+      rev = "v${version}";
+      hash = "sha256-RepuvqNPHRGENupPG5ezadn6f7FxEUYFDi4+DpNanuA=";
+    };
+
+    nativeBuildInputs = [
+      meson
+      ninja
+      pkg-config
+      cmake
+      desktop-file-utils # update-desktop-database
+      wrapGAppsHook4
+    ];
+
+    buildInputs = [
+      onnxruntime
+      libadwaita
+      libpulseaudio
+      xorg.libX11
+    ];
+
+    postUnpack = ''
+      rm -r source/subprojects/april-asr
+      ln -sf ${aprilAsr} source/subprojects/april-asr
+    '';
+
+    preFixup = ''
+      gappsWrapperArgs+=(
+        --set APRIL_MODEL_PATH ${aprilModel}
+      )
+    '';
+
+    meta = with lib; {
+      description = "Linux Desktop application that provides live captioning";
+      homepage = "https://github.com/abb128/LiveCaptions";
+      license = licenses.gpl3Plus;
+      platforms = platforms.linux;
+      maintainers = with maintainers; [Scrumplex];
+    };
+  }

pkgs/top-level/all-packages.nix

@@ -1033,6 +1033,8 @@ with pkgs;
 
   libredirect = callPackage ../build-support/libredirect { };
 
+  livecaptions = callPackage ../applications/misc/livecaptions { };
+
   madonctl = callPackage ../applications/misc/madonctl { };
 
   copyDesktopItems = makeSetupHook {