mongodb-cli: init at 2.0.3 (#396467)

maintainers/maintainer-list.nix

@@ -10037,6 +10037,12 @@
     github = "I-Al-Istannen";
     githubId = 20284688;
   };
+  iamanaws = {
+    email = "nixpkgs.yjzaw@slmail.me";
+    github = "Iamanaws";
+    githubId = 78835633;
+    name = "Angel J";
+  };
   iammrinal0 = {
     email = "nixpkgs@mrinalpurohit.in";
     matrix = "@iammrinal0:nixos.dev";

pkgs/by-name/mo/mongodb-cli/package.nix

@@ -0,0 +1,41 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  lib,
+  buildGoModule,
+  installShellFiles,
+}:
+
+buildGoModule rec {
+  pname = "mongodb-cli";
+  version = "2.0.3";
+
+  src = fetchFromGitHub {
+    owner = "mongodb";
+    repo = "mongodb-cli";
+    tag = "mongocli/v${version}";
+    sha256 = "sha256-vhx8dxTNngDBy+34e+Er7uqIAGJImJiPmwxZX+EwIG0=";
+  };
+
+  vendorHash = "sha256-825S3jMwgZC3aInuahg6/jg4A9u/bKeie30MB9HexJY=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  subPackages = [ "cmd/mongocli" ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd mongocli \
+      --bash <($out/bin/mongocli completion bash) \
+      --fish <($out/bin/mongocli completion fish) \
+      --zsh <($out/bin/mongocli completion zsh)
+  '';
+
+  meta = {
+    description = "MongoDB CLI enable you to manage your MongoDB via ops manager and cloud manager";
+    homepage = "https://github.com/mongodb/mongodb-cli";
+    changelog = "https://www.mongodb.com/docs/mongocli/current/release-notes/#mongodb-cli-${version}";
+    license = lib.licenses.asl20;
+    maintainers = [ lib.maintainers.iamanaws ];
+    mainProgram = "mongocli";
+  };
+}