cagent: init at 1.19.0 (#479102)

maintainers/maintainer-list.nix

@@ -16996,6 +16996,13 @@
     githubId = 68288772;
     name = "Markus Heinrich";
   };
+  MH0386 = {
+    name = "Mohamed Hisham Abdelzaher";
+    email = "mohamed.hisham.abdelzaher@gmail.com";
+    github = "MH0386";
+    githubId = 77013511;
+    matrix = "@mh0386:matrix.org";
+  };
   mh182 = {
     email = "mh182@chello.at";
     github = "mh182";

pkgs/by-name/ca/cagent/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  buildGoModule,
+  fetchFromGitHub,
+  versionCheckHook,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "cagent";
+  version = "1.19.0";
+
+  src = fetchFromGitHub {
+    owner = "docker";
+    repo = "cagent";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-J7IRlSsjXRDvbUKwnV2rrWnEmvqciJw3mN8NerQBtl4=";
+  };
+
+  vendorHash = "sha256-q7mP9JWJEdDbUO/3MHsJwiySNvN2SbhnhEbJArnCW3M=";
+
+  # Disable tests: Networked model providers and writable cache directories are required.
+  doCheck = false;
+
+  # Skip install checks on macOS: The build sandbox is missing the `/etc/protocols` file, which is required for validation.
+  doInstallCheck = !stdenv.hostPlatform.isDarwin;
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "version";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X"
+    "github.com/docker/cagent/pkg/version.Version=${finalAttrs.version}"
+    "-X"
+    "github.com/docker/cagent/pkg/version.Commit=${finalAttrs.src.tag}"
+  ];
+
+  meta = {
+    description = "Agent Builder and Runtime by Docker Engineering";
+    longDescription = ''
+      A powerful, easy-to-use, customizable multi-agent runtime that
+      orchestrates AI agents with specialized capabilities and tools,
+      and the interactions between agents.
+    '';
+    homepage = "https://github.com/docker/cagent";
+    changelog = "https://github.com/docker/cagent/releases/tag/v${finalAttrs.version}";
+    downloadPage = "https://github.com/docker/cagent/releases";
+    license = lib.licenses.asl20;
+    mainProgram = "cagent";
+    maintainers = with lib.maintainers; [ MH0386 ];
+  };
+})