coc-stylelint: migrate from nodePackages

pkgs/applications/editors/vim/plugins/cocPlugins.nix

@@ -29,6 +29,7 @@
   coc-snippets,
   coc-solargraph,
   coc-spell-checker,
+  coc-stylelint,
   coc-sqlfluff,
   coc-toml,
 }:
@@ -181,6 +182,11 @@ final: prev: {
     src = "${coc-spell-checker}/lib/node_modules/coc-spell-checker";
   };
 
+  coc-stylelint = buildVimPlugin {
+    inherit (coc-stylelint) pname version meta;
+    src = "${coc-stylelint}/lib/node_modules/coc-stylelint";
+  };
+
   coc-sqlfluff = buildVimPlugin {
     inherit (coc-sqlfluff) pname version meta;
     src = "${coc-sqlfluff}/lib/node_modules/coc-sqlfluff";

pkgs/applications/editors/vim/plugins/nodePackagePlugins.nix

@@ -8,7 +8,6 @@ let
   nodePackageNames = [
     "coc-go"
     "coc-ltex"
-    "coc-stylelint"
     "coc-sumneko-lua"
     "coc-tabnine"
     "coc-texlab"

pkgs/by-name/co/coc-stylelint/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  fetchYarnDeps,
+  yarnConfigHook,
+  yarnBuildHook,
+  yarnInstallHook,
+  nodejs,
+  nix-update-script,
+}:
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "coc-stylelint";
+  version = "1.2.0";
+
+  src = fetchFromGitHub {
+    owner = "neoclide";
+    repo = "coc-stylelint";
+    tag = finalAttrs.version;
+    hash = "sha256-EurfiE1xeJhyH4Idb/hf/eItwmv75lan1csz0KJMBXs=";
+  };
+
+  # Fix yarn.lock file
+  postPatch = ''
+    substituteInPlace yarn.lock \
+      --replace-fail "http://registry.npmjs.org" "https://registry.yarnpkg.com"
+  '';
+
+  yarnOfflineCache = fetchYarnDeps {
+    inherit (finalAttrs) src postPatch;
+    hash = "sha256-rcHjbiMDrgCHweRMDlfcMvAJT4VULks44fbpctPpZps=";
+  };
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    yarnBuildHook
+    yarnInstallHook
+    nodejs
+  ];
+
+  NODE_OPTIONS = "--openssl-legacy-provider";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Stylelint extension for coc.nvim";
+    homepage = "https://github.com/neoclide/coc-stylelint";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ pyrox0 ];
+  };
+})

pkgs/development/node-packages/aliases.nix

@@ -104,6 +104,7 @@ mapAliases {
   inherit (pkgs) coc-solargraph; # Added 2025-11-05
   inherit (pkgs) coc-spell-checker; # added 2025-10-01
   inherit (pkgs) coc-sqlfluff; # Added 2025-11-05
+  inherit (pkgs) coc-stylelint; # Added 2025-11-05
   inherit (pkgs) coc-toml;
   coc-tslint = throw "coc-tslint was removed because it was deprecated upstream; coc-eslint offers comparable features for eslint, which replaced tslint"; # Added 2024-10-18
   coc-tslint-plugin = throw "coc-tslint-plugin was removed because it was deprecated upstream; coc-eslint offers comparable features for eslint, which replaced tslint"; # Added 2024-10-18

pkgs/development/node-packages/node-packages.json

@@ -23,7 +23,6 @@
 , "clipboard-cli"
 , "coc-go"
 , "coc-ltex"
-, "coc-stylelint"
 , "coc-sumneko-lua"
 , "coc-tabnine"
 , "coc-texlab"