silver-searcher-ng: init at 2.2.0

This partially reverts commit 6d25325931.

pkgs/by-name/si/silver-searcher-ng/bash-completion.patch

@@ -0,0 +1,5 @@
+--- a/Makefile.am
++++ b/Makefile.am
+@@ -9 +9 @@
+-bashcompdir = $(pkgdatadir)/completions
++bashcompdir = $(datadir)/bash-completion/completions

pkgs/by-name/si/silver-searcher-ng/package.nix

@@ -0,0 +1,55 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  autoreconfHook,
+  pkg-config,
+  pcre,
+  zlib,
+  xz,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "silver-searcher-ng";
+  version = "2.2.0";
+
+  src = fetchFromGitHub {
+    owner = "silver-searcher";
+    repo = "silver-searcher-ng";
+    rev = finalAttrs.version;
+    sha256 = "0cyazh7a66pgcabijd27xnk1alhsccywivv6yihw378dqxb22i1p";
+  };
+
+  patches = [ ./bash-completion.patch ];
+
+  env = {
+    # Workaround build failure on -fno-common toolchains like upstream
+    # gcc-10. Otherwise build fails as:
+    #   ld: src/zfile.o:/build/source/src/log.h:12: multiple definition of
+    #     `print_mtx'; src/ignore.o:/build/source/src/log.h:12: first defined here
+    # TODO: remove once next release has https://github.com/ggreer/the_silver_searcher/pull/1377
+    NIX_CFLAGS_COMPILE = "-fcommon";
+  }
+  // lib.optionalAttrs stdenv.hostPlatform.isLinux {
+    NIX_LDFLAGS = "-lgcc_s";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+  ];
+  buildInputs = [
+    pcre
+    zlib
+    xz
+  ];
+
+  meta = {
+    homepage = "https://github.com/silver-searcher/silver-searcher-ng";
+    description = "Code-searching tool similar to ack, but faster";
+    maintainers = with lib.maintainers; [ timschumi ];
+    mainProgram = "ag";
+    platforms = lib.platforms.all;
+    license = lib.licenses.asl20;
+  };
+})

pkgs/top-level/aliases.nix

@@ -1974,7 +1974,7 @@ mapAliases {
   sierra-breeze-enhanced = throw "'sierra-breeze-enhanced' has been removed, as it is only compatible with Plasma 5, which is EOL"; # Added 2025-08-20
   signal-desktop-bin = throw "'signal-desktop-bin' has been replaced by 'signal-desktop' which is built from source"; # Added 2026-03-02
   signal-desktop-source = throw "'signal-desktop-source' has been renamed to/replaced by 'signal-desktop'"; # Converted to throw 2025-10-27
-  silver-searcher = throw "'silver-searcher' has been removed as it has seen no development since 2020 and is stuck on the obsolete pcre library";
+  silver-searcher = throw "'silver-searcher' has been removed as it has seen no development since 2020 and is stuck on the obsolete pcre library. Consider using 'silver-searcher-ng', which is a fork with support for PCRE2.";
   simpleBluez = warnAlias "'simpleBluez' has been renamed to 'simplebluez'" simplebluez; # Added 2026-02-18
   simpleDBus = warnAlias "'simpleDBus' has been renamed to 'simpledbus'" simpledbus; # Added 2026-02-12
   simplesamlphp = throw "'simplesamlphp' was removed because it was unmaintained in nixpkgs"; # Added 2025-10-17