opencamlib: init at 2023.01.11, and use in freecad (#400063)

maintainers/maintainer-list.nix

@@ -24749,6 +24749,12 @@
     githubId = 13155277;
     name = "Tom Houle";
   };
+  tomjnixon = {
+    name = "Tom Nixon";
+    email = "nixpkgs@tomn.co.uk";
+    github = "tomjnixon";
+    githubId = 178226;
+  };
   tomkoid = {
     email = "tomaszierl@outlook.com";
     name = "Tomkoid";

pkgs/by-name/fr/freecad/package.nix

@@ -44,6 +44,7 @@ let
     gitpython
     ifcopenshell
     matplotlib
+    opencamlib
     pivy
     ply
     py-slvs
@@ -104,6 +105,7 @@ freecad-utils.makeCustomizable (
         medfile
         mpi
         ode
+        opencamlib
         pivy
         ply # for openSCAD file support
         py-slvs

pkgs/development/python-modules/opencamlib/default.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  scikit-build-core,
+  cmake,
+  ninja,
+  stdenv,
+  llvmPackages,
+  boost,
+  python,
+}:
+
+buildPythonPackage rec {
+  pname = "opencamlib";
+  version = "2023.01.11";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "aewallin";
+    repo = "opencamlib";
+    tag = version;
+    hash = "sha256-pUj71PdWo902dqF9O6SLnpvFooFU2OfLBv8hAVsH/iA=";
+  };
+
+  build-system = [
+    scikit-build-core
+  ];
+
+  buildInputs = [
+    boost
+  ] ++ lib.optionals stdenv.cc.isClang [ llvmPackages.openmp ];
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+  ];
+
+  postPatch = ''
+    substituteInPlace pyproject.toml \
+      --replace-fail 'version = "2022.12.18"' 'version = "${version}"'
+  '';
+
+  dontUseCmakeConfigure = true;
+  env.CMAKE_ARGS = "-DVERSION_STRING=${version} -DBoost_USE_STATIC_LIBS=OFF";
+
+  pythonImportsCheck = [ "opencamlib" ];
+
+  checkPhase = ''
+    runHook preCheck
+
+    pushd examples/python
+    # this produces a lot of non-actionalble lines on stdout
+    ${python.interpreter} test.py > /dev/null
+    popd
+
+    runHook postCheck
+  '';
+
+  meta = {
+    homepage = "https://github.com/aewallin/opencamlib";
+    description = "Open source computer aided manufacturing algorithms library";
+    # from src/deb/debian_copyright.txt
+    license = lib.licenses.lgpl21Plus;
+    maintainers = with lib.maintainers; [ tomjnixon ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -10277,6 +10277,8 @@ self: super: with self; {
     openbabel = callPackage ../development/libraries/openbabel { inherit (self) python; };
   };
 
+  opencamlib = callPackage ../development/python-modules/opencamlib { };
+
   opencensus = callPackage ../development/python-modules/opencensus { };
 
   opencensus-context = callPackage ../development/python-modules/opencensus-context { };