beammp-launcher: init at 2.7.0

beammp-launcher: hardcode derivation attributes beammp-launcher: use finalAttrs instead of rec beammp-launcher: used `strictDeps` to better determine dependencies beammp-launcher: 2.5.1 -> 2.6.3 beammp-launcher: 2.6.3 -> 2.6.4 beammp-launcher: 2.6.4 -> 2.7.0
2025-10-27 14:05:19 +02:00
parent 6030099064
commit 65f42173f1
1 changed files with 69 additions and 0 deletions
@@ -0,0 +1,69 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  lib,
+  copyDesktopItems,
+  installShellFiles,
+  makeDesktopItem,
+
+  cmake,
+  curl,
+  httplib,
+  nlohmann_json,
+  openssl,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "beammp-launcher";
+  version = "2.7.0";
+
+  src = fetchFromGitHub {
+    owner = "BeamMP";
+    repo = "BeamMP-Launcher";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-+qdDGOLds2j00BRijFAZ8DMrnjvigs+z+w9+wbitJno=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    copyDesktopItems
+    installShellFiles
+
+    cmake
+  ];
+
+  buildInputs = [
+    curl
+    httplib
+    nlohmann_json
+    openssl
+  ];
+
+  desktopItems = [
+    (makeDesktopItem {
+      categories = [ "Game" ];
+      comment = "Launcher for the BeamMP mod for BeamNG.drive";
+      desktopName = "BeamMP-Launcher";
+      exec = "BeamMP-Launcher";
+      name = "BeamMP-Launcher";
+      terminal = true;
+    })
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    installBin "BeamMP-Launcher"
+    copyDesktopItems
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Launcher for the BeamMP mod for BeamNG.drive";
+    homepage = "https://github.com/BeamMP/BeamMP-Launcher";
+    license = lib.licenses.agpl3Only;
+    mainProgram = "BeamMP-Launcher";
+    maintainers = [ lib.maintainers.Andy3153 ];
+    platforms = lib.platforms.linux;
+  };
+})