clipse: 1.1.0 -> 1.2.1

Version 1.2.0 of `clipse` has build requirements that are specific to
the host display server. The `clipse-x11` alias has been added for those
using the x11 display server.

Release: https://github.com/savedra1/clipse/releases/tag/v1.2.0
Release: https://github.com/savedra1/clipse/releases/tag/v1.2.1

Co-authored-by: savedra1 <michaelsavedra@gmail.com>

pkgs/by-name/cl/clipse/package.nix

@@ -2,20 +2,71 @@
   lib,
   buildGoModule,
   fetchFromGitHub,
+  stdenv,
+  enableWayland ? stdenv.hostPlatform.isLinux,
+  enableX11 ? false,
+  libpng,
+  libx11,
+  libxi,
+  libxkbcommon,
+  libxtst,
+  pkg-config,
+  xclip,
+  xinput,
+  xkbcomp,
+  xkbutils,
+  xsel,
 }:
 
+assert lib.assertMsg (
+  stdenv.hostPlatform.isLinux -> (lib.xor enableX11 enableWayland)
+) "Exactly one of enableWayland, enableX11 must be true";
+
 buildGoModule (finalAttrs: {
-  pname = "clipse";
-  version = "1.1.0";
+  pname = "clipse${lib.optionalString enableX11 "-x11"}";
+  version = "1.2.1";
 
   src = fetchFromGitHub {
     owner = "savedra1";
     repo = "clipse";
-    rev = "v${finalAttrs.version}";
-    hash = "sha256-yUkHT7SZT7Eudvk1n43V+WGWqUKtXaV+p4ySMK/XzQw=";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-iDMHEhYuxspBYG54WivnVj2GfMxAc5dcrjNxtAMhsck=";
   };
 
-  vendorHash = "sha256-+9uoB/1g4qucdM8RJRs+fSc5hpcgaCK0GrUOFgHWeKo=";
+  vendorHash = "sha256-LxwST4Zjxq6Fwc47VeOdv19J3g/DHZ7Fywp2ZvVR06I=";
+
+  tags =
+    if stdenv.hostPlatform.isDarwin then
+      [ "darwin" ]
+    else if enableWayland then
+      [ "wayland" ]
+    else if enableX11 then
+      [ "linux" ]
+    else
+      [ ];
+
+  env = {
+    CGO_ENABLED = if enableX11 || stdenv.hostPlatform.isDarwin then "1" else "0";
+  };
+
+  nativeBuildInputs = lib.optionals enableX11 [
+    pkg-config
+  ];
+
+  buildInputs = lib.optionals enableX11 [
+    libpng
+    libx11
+    libxi
+    libxkbcommon
+    libxtst
+    xclip
+    xinput
+    xkbcomp
+    xkbutils
+    xsel
+  ];
+
+  proxyVendor = true;
 
   meta = {
     description = "Useful clipboard manager TUI for Unix";

pkgs/top-level/all-packages.nix

@@ -11629,4 +11629,9 @@ with pkgs;
   gpac-unstable = callPackage ../by-name/gp/gpac/package.nix {
     releaseChannel = "unstable";
   };
+
+  clipse-x11 = callPackage ../by-name/cl/clipse/package.nix {
+    enableWayland = false;
+    enableX11 = true;
+  };
 }