dput-ng: Add missing dependency python3Packages.distro-info, install required configuration files (#417346)

pkgs/by-name/di/distro-info-data/package.nix

@@ -0,0 +1,29 @@
+{
+  fetchFromGitLab,
+  lib,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "distro-info-data";
+  version = "0.67";
+
+  src = fetchFromGitLab {
+    domain = "salsa.debian.org";
+    owner = "debian";
+    repo = "distro-info-data";
+    tag = "debian/${finalAttrs.version}";
+    hash = "sha256-xm/ajsPKtnmuyEkVxM1AxV7Tl0njkqjOmhE5rKRQ36Q=";
+  };
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = {
+    description = "Information about Debian and Ubuntu releases";
+    homepage = "https://salsa.debian.org/debian/distro-info-data";
+    changelog = "https://salsa.debian.org/debian/distro-info-data/-/blob/${finalAttrs.src.tag}/debian/changelog";
+    license = lib.licenses.isc;
+    maintainers = with lib.maintainers; [ andersk ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/dp/dput-ng/package.nix

@@ -20,6 +20,10 @@ python3.pkgs.buildPythonApplication {
     hash = "sha256-zrH4h4C4y3oTiOXsidFv/rIJNzCdV2lqzNEg0SOkX4w=";
   };
 
+  postPatch = ''
+    substituteInPlace dput/core.py --replace-fail /usr/share/dput-ng "$out/share/dput-ng"
+  '';
+
   build-system = with python3.pkgs; [
     setuptools
   ];
@@ -31,10 +35,13 @@ python3.pkgs.buildPythonApplication {
     coverage
     xdg
     python-debian
+    distro-info
   ];
 
   postInstall = ''
     cp -r bin $out/
+    mkdir -p "$out/share/dput-ng"
+    cp -r skel/* "$out/share/dput-ng/"
   '';
 
   pythonImportsCheck = [ "dput" ];

pkgs/development/python-modules/distro-info/default.nix

@@ -0,0 +1,45 @@
+{
+  buildPythonPackage,
+  distro-info-data,
+  fetchurl,
+  lib,
+  setuptools,
+  unittestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "distro-info";
+  version = "1.14";
+  pyproject = true;
+
+  # Not using fetchFromGitLab because it incorrectly sets
+  # SOURCE_DATE_EPOCH=315619200 (1980-01-02) and breaks tests.
+  src = fetchurl {
+    url = "https://salsa.debian.org/debian/distro-info/-/archive/debian/${version}/distro-info-debian-${version}.tar.gz";
+    hash = "sha256-nRLTlDPnll1jvwfg9FSxs9TmImvQkn9DVqSRSOKTAGI=";
+  };
+
+  postPatch = ''
+    substituteInPlace python/distro_info.py \
+      --replace-fail /usr/share/distro-info ${distro-info-data}/share/distro-info
+  '';
+
+  build-system = [ setuptools ];
+  pypaBuildFlags = "python";
+  nativeCheckInputs = [
+    unittestCheckHook
+  ];
+  preCheck = ''
+    cd python
+    rm distro_info_test/test_flake8.py distro_info_test/test_pylint.py
+  '';
+
+  meta = {
+    description = "Information about Debian and Ubuntu releases";
+    homepage = "https://salsa.debian.org/debian/distro-info";
+    changelog = "https://salsa.debian.org/debian/distro-info/-/blob/debian/${version}/debian/changelog";
+    license = lib.licenses.isc;
+    maintainers = with lib.maintainers; [ andersk ];
+    platforms = lib.platforms.all;
+  };
+}

pkgs/top-level/python-packages.nix

@@ -3812,6 +3812,8 @@ self: super: with self; {
 
   distro = callPackage ../development/python-modules/distro { };
 
+  distro-info = callPackage ../development/python-modules/distro-info { };
+
   distutils =
     if pythonOlder "3.12" then null else callPackage ../development/python-modules/distutils { };