river-bedload: init at 0.1.1-unstable-2025-03-19 (#418433)

pkgs/by-name/ri/river-bedload/build.zig.zon.nix

@@ -0,0 +1,17 @@
+# generated by zon2nix (https://github.com/nix-community/zon2nix)
+
+{
+  linkFarm,
+  fetchzip,
+  fetchgit,
+}:
+
+linkFarm "zig-packages" [
+  {
+    name = "wayland-0.3.0-lQa1kjPIAQDmhGYpY-zxiRzQJFHQ2VqhJkQLbKKdt5wl";
+    path = fetchzip {
+      url = "https://codeberg.org/ifreund/zig-wayland/archive/v0.3.0.tar.gz";
+      hash = "sha256-ydEavD9z20wRwn9ZVX56ZI2T5i1tnm3LupVxfa30o84=";
+    };
+  }
+]

pkgs/by-name/ri/river-bedload/package.nix

@@ -0,0 +1,58 @@
+{
+  _experimental-update-script-combinators,
+  callPackage,
+  fetchFromSourcehut,
+  unstableGitUpdater,
+  lib,
+  pkg-config,
+  stdenv,
+  river,
+  wayland,
+  wayland-protocols,
+  wayland-scanner,
+  zig,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "river-bedload";
+  version = "0.1.1-unstable-2025-03-19";
+
+  src = fetchFromSourcehut {
+    owner = "~novakane";
+    repo = "river-bedload";
+    rev = "4a2855ca2669372c346975dd6e1f612ca563b131";
+    hash = "sha256-CQH2LQi2ga4YDD2ZYb998ExDJHK4TGHq5h3z94703Dc=";
+  };
+
+  deps = callPackage ./build.zig.zon.nix { };
+
+  nativeBuildInputs = [
+    pkg-config
+    zig.hook
+  ];
+
+  buildInputs = [
+    wayland
+    wayland-protocols
+    wayland-scanner
+  ];
+
+  zigBuildFlags = [
+    "--system"
+    "${finalAttrs.deps}"
+  ];
+
+  passthru.updateScript = _experimental-update-script-combinators.sequence [
+    (unstableGitUpdater { tagPrefix = "v"; })
+    ./update-build-zig-zon.sh
+  ];
+
+  meta = {
+    description = "Display information about river in json in the STDOUT";
+    homepage = "https://git.sr.ht/~novakane/river-bedload";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ adamcstephens ];
+    mainProgram = "river-bedload";
+    inherit (river.meta) platforms;
+  };
+})

pkgs/by-name/ri/river-bedload/update-build-zig-zon.sh

@@ -0,0 +1,10 @@
+#!/usr/bin/env nix-shell
+#!nix-shell -i bash -p bash jq nixfmt-rfc-style zon2nix
+
+commit=$(nix-instantiate --eval -A river-bedload.src.rev | jq --raw-output)
+
+wget "https://git.sr.ht/~novakane/river-bedload/blob/${commit}/build.zig.zon"
+zon2nix build.zig.zon >pkgs/by-name/ri/river-bedload/build.zig.zon.nix
+nixfmt pkgs/by-name/ri/river-bedload/build.zig.zon.nix
+
+rm -f build.zig.zon