python312Packages.fnllm: init at 0.0.11, python311Packages.graphrag: 0.5.0 -> 0.9.0 (#364162)

pkgs/development/python-modules/fnllm/default.nix

@@ -0,0 +1,80 @@
+{
+  lib,
+  aiolimiter,
+  azure-identity,
+  azure-storage-blob,
+  buildPythonPackage,
+  fetchPypi,
+  hatchling,
+  httpx,
+  json-repair,
+  openai,
+  pydantic,
+  pytest-asyncio,
+  pytestCheckHook,
+  pythonOlder,
+  tenacity,
+  tiktoken,
+}:
+
+buildPythonPackage rec {
+  pname = "fnllm";
+  version = "0.0.11";
+  pyproject = true;
+
+  disabled = pythonOlder "3.11";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-EiCP+HyipL6mpmjb3wjXUr+VRJ9ZO9qsegppNM7gVEk=";
+  };
+
+  build-system = [ hatchling ];
+
+  dependencies = [
+    aiolimiter
+    httpx
+    json-repair
+    pydantic
+    tenacity
+  ];
+
+  optional-dependencies = {
+    azure = [
+      azure-identity
+      azure-storage-blob
+    ];
+    openai = [
+      openai
+      tiktoken
+    ];
+  };
+
+  nativeCheckInputs = [
+    pytest-asyncio
+    pytestCheckHook
+  ] ++ lib.flatten (builtins.attrValues optional-dependencies);
+
+  pythonImportsCheck = [ "fnllm" ];
+
+  disabledTests = [
+    # Tests require network access
+    "chat"
+    "embeddings"
+    "rate_limited"
+    "test_default_operations"
+    "test_estimate_request_tokens"
+    "test_replace_value"
+  ];
+
+  disabledTestPaths = [
+    "tests/unit/caching/test_blob.py"
+  ];
+
+  meta = {
+    description = "A function-based LLM protocol and wrapper";
+    homepage = "https://github.com/microsoft/essex-toolkit/tree/main/python/fnllm";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ fab ];
+  };
+}

pkgs/development/python-modules/graphrag/default.nix

@@ -12,6 +12,7 @@
   datashaper,
   devtools,
   environs,
+  fnllm,
   graspologic,
   json-repair,
   lancedb,
@@ -39,14 +40,14 @@
 
 buildPythonPackage rec {
   pname = "graphrag";
-  version = "0.5.0";
+  version = "0.9.0";
   pyproject = true;
 
   src = fetchFromGitHub {
     owner = "microsoft";
     repo = "graphrag";
     rev = "refs/tags/v${version}";
-    hash = "sha256-QK6ZdBDSSKi/WUsDQeEY5JfxgsmW/vK7yDfjMseAO/k=";
+    hash = "sha256-LD7cfea8uyCYVMhsHXQBHho7jiwEmlqYrrfZs/7oeyc=";
   };
 
   build-system = [
@@ -65,6 +66,7 @@ buildPythonPackage rec {
     datashaper
     devtools
     environs
+    fnllm
     graspologic
     json-repair
     lancedb

pkgs/top-level/python-packages.nix

@@ -4856,6 +4856,8 @@ self: super: with self; {
 
   glyphtools = callPackage ../development/python-modules/glyphtools { };
 
+  fnllm = callPackage ../development/python-modules/fnllm { };
+
   foobot-async = callPackage ../development/python-modules/foobot-async { };
 
   foolscap = callPackage ../development/python-modules/foolscap { };