tiddit: init at 3.6.1 (#312995)

2024-12-05 15:50:06 +08:00
parent 833953e741 196f141973
commit 54f3a0cc7f
3 changed files with 118 additions and 0 deletions
@@ -0,0 +1,34 @@
+{
+  config,
+  lib,
+  fetchFromGitHub,
+  zlib,
+  stdenv,
+}:
+stdenv.mkDerivation {
+  pname = "fermi2";
+  version = "0.1-unstable-2021-05-21";
+  src = fetchFromGitHub {
+    owner = "lh3";
+    repo = "fermi2";
+    rev = "cb1410972b2bd330883823116931ae67ead8b30f";
+    hash = "sha256-jDn1OBuGWDMEHI5A3R9meOykEGM6yjItSnUpx36DxgA=";
+  };
+  buildInputs = [ zlib ];
+  makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 fermi2 -t $out/bin
+
+    runHook postInstall
+  '';
+  meta = {
+    homepage = "https://github.com/lh3/fermi2";
+    description = "Successor of fermi, a whole genome de novo assembler based on the FMD-index for large genomes";
+    mainProgram = "fermi2";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ apraga ];
+    platforms = lib.intersectLists lib.platforms.x86_64 lib.platforms.unix;
+  };
+}
@@ -0,0 +1,33 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  zlib,
+}:
+stdenv.mkDerivation {
+  name = "ropebwt2";
+  version = "0-unstable-2021-02-01";
+  src = fetchFromGitHub {
+    owner = "lh3";
+    repo = "ropebwt2";
+    rev = "bd8dbd3db2e9e3cff74acc2907c0742c9ebbf033";
+    hash = "sha256-R/VvbprwcfXF2TBZOYmc1MU3AzCcXFfWCHoYYumXtI8=";
+  };
+  buildInputs = [ zlib ];
+  makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 ropebwt2 -t $out/bin
+
+    runHook postInstall
+  '';
+  meta = {
+    homepage = "https://github.com/lh3/ropebwt2";
+    description = "Incremental construction of FM-index for DNA sequences";
+    mainProgram = "ropebwt2";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ apraga ];
+    platforms = lib.platforms.unix;
+  };
+}
@@ -0,0 +1,51 @@
+{
+  bwa,
+  lib,
+  fermi2,
+  ropebwt2,
+  fetchFromGitHub,
+  python3Packages,
+}:
+python3Packages.buildPythonApplication rec {
+  name = "tiddit";
+  version = "3.6.1";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "SciLifeLab";
+    repo = "TIDDIT";
+    rev = "refs/tags/TIDDIT-${version}";
+    hash = "sha256-OeqVQJDw0fmSDWIGab2qtTJCzZxqLY2XzRqaTRuPIdI=";
+  };
+
+  build-system = with python3Packages; [
+    setuptools
+    wheel
+  ];
+
+  dependencies = with python3Packages; [
+    cython
+    joblib
+    numpy
+    pysam
+  ];
+
+  makeWrapperArgs = [
+    "--prefix PATH : ${
+      lib.makeBinPath [
+        bwa
+        fermi2
+        ropebwt2
+      ]
+    }"
+  ];
+
+  meta = {
+    homepage = "https://github.com/SciLifeLab/TIDDIT";
+    description = "Identify chromosomal rearrangements using Mate Pair or Paired End sequencing data";
+    mainProgram = "tiddit";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ apraga ];
+    platforms = lib.platforms.unix;
+  };
+}