python3Packages.google-cloud-storage-control: init at 1.9.0

pkgs/development/python-modules/google-cloud-storage-control/default.nix

@@ -0,0 +1,68 @@
+{
+  buildPythonPackage,
+  fetchFromGitHub,
+  gitUpdater,
+  google-api-core,
+  google-auth,
+  grpc-google-iam-v1,
+  grpcio,
+  lib,
+  proto-plus,
+  protobuf,
+  pytest-asyncio,
+  pytestCheckHook,
+  setuptools,
+}:
+
+buildPythonPackage (finalAttrs: {
+  pname = "google-cloud-storage-control";
+  version = "1.9.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "googleapis";
+    repo = "google-cloud-python";
+    tag = "google-cloud-storage-control-v${finalAttrs.version}";
+    hash = "sha256-5xQ4p9xi/6Y8oi7dWo+fdVT8X8U7UGmdKtSsoEanRso=";
+  };
+
+  sourceRoot = "${finalAttrs.src.name}/packages/google-cloud-storage-control";
+
+  build-system = [ setuptools ];
+
+  dependencies = [
+    google-api-core
+    google-auth
+    grpc-google-iam-v1
+    grpcio
+    proto-plus
+    protobuf
+  ]
+  ++ google-api-core.optional-dependencies.grpc;
+
+  pythonImportsCheck = [
+    "google.cloud.storage_control"
+    "google.cloud.storage_control_v2"
+  ];
+
+  nativeCheckInputs = [
+    pytest-asyncio
+    pytestCheckHook
+  ];
+
+  passthru = {
+    # bulk updater selects wrong tag
+    skipBulkUpdate = true;
+    updateScript = gitUpdater {
+      rev-prefix = "google-cloud-storage-control-v";
+    };
+  };
+
+  meta = {
+    changelog = "https://github.com/googleapis/google-cloud-python/blob/${finalAttrs.src.tag}/packages/google-cloud-storage-control/CHANGELOG.md";
+    description = "Google Cloud Storage Control API client library";
+    homepage = "https://github.com/googleapis/google-cloud-python/tree/main/packages/google-cloud-storage-control";
+    license = lib.licenses.asl20;
+    maintainers = [ lib.maintainers.dotlambda ];
+  };
+})

pkgs/top-level/python-packages.nix

@@ -6406,6 +6406,10 @@ self: super: with self; {
 
   google-cloud-storage = callPackage ../development/python-modules/google-cloud-storage { };
 
+  google-cloud-storage-control =
+    callPackage ../development/python-modules/google-cloud-storage-control
+      { };
+
   google-cloud-tasks = callPackage ../development/python-modules/google-cloud-tasks { };
 
   google-cloud-testutils = callPackage ../development/python-modules/google-cloud-testutils { };