vscode-extensions.oxc.oxc-vscode: init at 1.55.0

pkgs/applications/editors/vscode/extensions/default.nix

@@ -3707,6 +3707,8 @@ let
 
       oracle.oracle-java = callPackage ./oracle.oracle-java { };
 
+      oxc.oxc-vscode = callPackage ./oxc.oxc-vscode { };
+
       ph-hawkins.arc-plus = callPackage ./ph-hawkins.arc-plus { };
 
       phind.phind = buildVscodeMarketplaceExtension {

pkgs/applications/editors/vscode/extensions/oxc.oxc-vscode/default.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  vscode-utils,
+  jaq,
+  moreutils,
+  oxlint,
+  oxfmt,
+}:
+vscode-utils.buildVscodeMarketplaceExtension {
+  mktplcRef = {
+    publisher = "oxc";
+    name = "oxc-vscode";
+    version = "1.55.0";
+    hash = "sha256-QAuN9Qe1AErcGIbbqsYYO6kikgaEiX0Y3ddnNhuOB6Q=";
+  };
+
+  nativeBuildInputs = [
+    jaq
+    moreutils
+  ];
+
+  postPatch = ''
+    jaq \
+      --arg oxlint "${lib.getExe oxlint}" \
+      --arg oxfmt "${lib.getExe oxfmt}" \
+      '
+        .contributes.configuration.properties."oxc.path.oxlint".default = $oxlint |
+        .contributes.configuration.properties."oxc.path.oxfmt".default = $oxfmt
+      ' package.json | sponge package.json
+  '';
+
+  meta = {
+    description = "Oxlint and Oxfmt editor integration";
+    downloadPage = "https://marketplace.visualstudio.com/items?itemName=oxc.oxc-vscode";
+    homepage = "https://github.com/oxc-project/oxc-vscode";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.drupol ];
+  };
+}