raysession: init at 0.13.1 (#222628)

Fixes #194022

pkgs/applications/audio/raysession/default.nix

@@ -0,0 +1,44 @@
+{ lib, fetchurl, buildPythonApplication, pydbus, pyliblo, pyqt5, qttools, which }:
+
+buildPythonApplication rec {
+  pname = "raysession";
+  version = "0.13.1";
+
+  src = fetchurl {
+    url = "https://github.com/Houston4444/RaySession/releases/download/v${version}/RaySession-${version}-source.tar.gz";
+    sha256 = "sha256-iiFRtX43u9BHe7a4ojza7kav+dMW9e05dPi7Gf9d1GM=";
+  };
+
+  postPatch = ''
+    # Fix installation path of xdg schemas.
+    substituteInPlace Makefile --replace '$(DESTDIR)/' '$(DESTDIR)$(PREFIX)/'
+    # Do not wrap an importable module with a shell script.
+    chmod -x src/daemon/desktops_memory.py
+  '';
+
+  format = "other";
+
+  nativeBuildInputs = [
+    pyqt5   # pyuic5 and pyrcc5 to build resources.
+    qttools # lrelease to build translations.
+    which   # which to find lrelease.
+  ];
+
+  propagatedBuildInputs = [ pydbus pyliblo pyqt5 ];
+
+  dontWrapQtApps = true; # The program is a python script.
+
+  installFlags = [ "PREFIX=$(out)" ];
+
+  postFixup = ''
+    wrapPythonProgramsIn "$out/share/raysession/src" "$out $pythonPath"
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/Houston4444/RaySession";
+    description = "Session manager for Linux musical programs";
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ orivej ];
+    platforms = platforms.linux;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -11372,6 +11372,10 @@ with pkgs;
 
   pystring = callPackage ../development/libraries/pystring { };
 
+  raysession = python3Packages.callPackage ../applications/audio/raysession {
+    inherit (qt5) qttools;
+  };
+
   rbw = callPackage ../tools/security/rbw {
     inherit (darwin.apple_sdk.frameworks) Security;
   };