python3Packages.nixpkgs-updaters-library: init at 1.0.2 (#376386)

pkgs/development/python-modules/nixpkgs-updaters-library/default.nix

@@ -0,0 +1,81 @@
+{
+  lib,
+  buildPythonPackage,
+  pythonOlder,
+  fetchFromGitHub,
+
+  # build-system
+  hatchling,
+
+  # dependencies
+  aiohttp,
+  attrs,
+  frozendict,
+  inject,
+  loguru,
+  nix,
+  nix-prefetch-git,
+  nonbloat-db,
+  nurl,
+  platformdirs,
+  typer,
+
+  # tests
+  pytestCheckHook,
+  aioresponses,
+  pytest-asyncio,
+  pytest-cov-stub,
+  pytest-mock,
+}:
+buildPythonPackage rec {
+  pname = "nixpkgs-updaters-library";
+  version = "1.0.2";
+  pyproject = true;
+
+  disabled = pythonOlder "3.12";
+
+  src = fetchFromGitHub {
+    owner = "PerchunPak";
+    repo = "nixpkgs-updaters-library";
+    tag = "v${version}";
+    hash = "sha256-SzGbsHy3Pwpr92512y/R3JLtC01jAveFavRGOYyr81U=";
+  };
+
+  postPatch = ''
+    substituteInPlace nupd/executables.py \
+      --replace-fail '"nurl"' '"${lib.getExe nurl}"' \
+      --replace-fail '"nix-prefetch-url"' '"${lib.getExe' nix "nix-prefetch-git"}"' \
+      --replace-fail '"nix-prefetch-git"' '"${lib.getExe' nix-prefetch-git "nix-prefetch-git"}"'
+  '';
+
+  build-system = [ hatchling ];
+
+  dependencies = [
+    aiohttp
+    attrs
+    frozendict
+    inject
+    loguru
+    nonbloat-db
+    platformdirs
+    typer
+    nix-prefetch-git
+    nurl
+  ];
+
+  nativeCheckInputs = [
+    aioresponses
+    pytest-asyncio
+    pytest-cov-stub
+    pytest-mock
+    pytestCheckHook
+  ];
+
+  meta = {
+    description = "Boilerplate-less updater library for Nixpkgs ecosystems";
+    homepage = "https://github.com/PerchunPak/nixpkgs-updaters-library";
+    changelog = "https://github.com/PerchunPak/nixpkgs-updaters-library/blob/v${version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ perchun ];
+  };
+}

pkgs/development/python-modules/nonbloat-db/default.nix

@@ -0,0 +1,71 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+
+  # build-system
+  poetry-core,
+  poetry-dynamic-versioning,
+
+  # dependencies
+  aiofile,
+  typing-extensions,
+
+  # tests
+  pytestCheckHook,
+  pytest-asyncio,
+  pytest-cov,
+  pytest-mock,
+  pytest-randomly,
+  faker,
+}:
+
+buildPythonPackage rec {
+  pname = "nonbloat-db";
+  version = "0.1.4";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "PerchunPak";
+    repo = "nonbloat-db";
+    tag = "v${version}";
+    hash = "sha256-x6QFOZ+RYdophuRXMKE4RNi1xDnsa3naUMDbn1vG7hM=";
+  };
+
+  build-system = [
+    poetry-core
+    poetry-dynamic-versioning
+  ];
+
+  dependencies = [
+    aiofile
+    typing-extensions
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    pytest-asyncio
+    pytest-cov
+    pytest-mock
+    pytest-randomly
+    faker
+  ];
+
+  pythonImportsCheck = [
+    "nbdb"
+    "nbdb.storage"
+  ];
+
+  disabledTests = [
+    # flaky
+    "test_write_in_background"
+  ];
+
+  meta = {
+    description = "Simple key-value database for my small projects";
+    homepage = "https://github.com/PerchunPak/nonbloat-db";
+    changelog = "https://github.com/PerchunPak/nonbloat-db/blob/v${version}/CHANGES.md";
+    license = lib.licenses.agpl3Only;
+    maintainers = with lib.maintainers; [ perchun ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -9125,6 +9125,8 @@ self: super: with self; {
 
   nomadnet = callPackage ../development/python-modules/nomadnet { };
 
+  nonbloat-db = callPackage ../development/python-modules/nonbloat-db { };
+
   noneprompt = callPackage ../development/python-modules/noneprompt {  };
 
   nox = callPackage ../development/python-modules/nox { };
@@ -9383,6 +9385,8 @@ self: super: with self; {
 
   nixpkgs-pytools = callPackage ../development/python-modules/nixpkgs-pytools { };
 
+  nixpkgs-updaters-library = callPackage ../development/python-modules/nixpkgs-updaters-library { };
+
   nix-prefetch-github = callPackage ../development/python-modules/nix-prefetch-github { };
 
   nkdfu = callPackage ../development/python-modules/nkdfu { };