uutils-{acl,procps,sed,util-linux}: init (#476177)

pkgs/by-name/uu/uutils-acl/package.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "uutils-acl";
+  version = "0.0.1-unstable-2026-01-08";
+
+  src = fetchFromGitHub {
+    owner = "uutils";
+    repo = "acl";
+    rev = "f5d374af73ec0206a6ea3106052550f873d5bcd8";
+    hash = "sha256-38Mp2ue89e7fLYaGwJsbkq+4l25gQDfVeJMY2ZAjJ8c=";
+  };
+
+  cargoHash = "sha256-5rHHhs+Hz0Yzvi5V1D2NPR6l5juP4BvjJve+8bbWbXc=";
+
+  checkFlags = [
+    # Operation not supported
+    "--skip=common::util::tests::test_compare_xattrs"
+    # assertion failed
+    "--skip=test_setfacl::test_invalid_arg"
+  ];
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [ "--version=branch" ];
+  };
+
+  meta = {
+    description = "Rust reimplementation of the acl project";
+    homepage = "https://github.com/uutils/acl";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ kyehn ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/uu/uutils-procps/package.nix

@@ -0,0 +1,61 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  writableTmpDirAsHomeHook,
+  systemdLibs,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "uutils-procps";
+  version = "0.0.1-unstable-2025-12-31";
+
+  src = fetchFromGitHub {
+    owner = "uutils";
+    repo = "procps";
+    rev = "644666759ec3e8f038a0d376b594e67a8780dc29";
+    hash = "sha256-U/5thGk/1h4CkI63DllLUc3scrHbV4+djcxLiTC+3lM=";
+  };
+
+  cargoHash = "sha256-kWT5PYE68TUcYnz82zxhiMIZFAn8Rf00Oj7oLsmzsG8=";
+
+  nativeBuildInputs = [
+    pkg-config
+    writableTmpDirAsHomeHook
+  ];
+
+  buildInputs = [ systemdLibs ];
+
+  checkFlags = [
+    # can't run on sandbox
+    "--skip=test_pgrep::test_count_with_matching_pattern"
+    "--skip=test_pgrep::test_list_full_process_with_empty_cmdline"
+    "--skip=test_pgrep::test_terminal_multiple_terminals"
+    "--skip=test_pgrep::test_unknown_terminal"
+    "--skip=test_pidof"
+    "--skip=test_pmap::test_device_permission_denied"
+    "--skip=test_pmap::test_extended_permission_denied"
+    "--skip=test_pmap::test_permission_denied"
+    "--skip=test_ps::test_deselect"
+    "--skip=test_ps::test_effective_group_selection"
+    "--skip=test_ps::test_effective_user_selection"
+    "--skip=test_ps::test_real_group_selection"
+    "--skip=test_ps::test_real_user_selection"
+    "--skip=test_pkill::test_inverse"
+    "--skip=test_pgrep::test_pidfile"
+  ];
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [ "--version=branch" ];
+  };
+
+  meta = {
+    description = "Rust reimplementation of the procps project";
+    homepage = "https://github.com/uutils/procps";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ kyehn ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/uu/uutils-sed/package.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "uutils-sed";
+  version = "0.1.1";
+
+  src = fetchFromGitHub {
+    owner = "uutils";
+    repo = "sed";
+    tag = finalAttrs.version;
+    hash = "sha256-y1X9nj/quBtisp+6MHFjVKFHrdFnujWTxLWNLvdrADA=";
+  };
+
+  cargoHash = "sha256-N5wwNPjOL3U4bPSONGpjmOBU31Nt/sCVth+JH3xmz/g=";
+
+  meta = {
+    changelog = "https://github.com/uutils/sed/releases/tag/${finalAttrs.version}";
+    description = "Rewrite of sed in Rust";
+    homepage = "https://github.com/uutils/sed";
+    license = lib.licenses.mit;
+    mainProgram = "sed";
+    maintainers = with lib.maintainers; [ kyehn ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/uu/uutils-util-linux/package.nix

@@ -0,0 +1,74 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  coreutils,
+  pkg-config,
+  util-linux,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "uutils-util-linux";
+  version = "0.0.1-unstable-2026-01-08";
+
+  src = fetchFromGitHub {
+    owner = "uutils";
+    repo = "util-linux";
+    rev = "8f87ce4641e8040eba624ffa99b73f73f73ab373";
+    hash = "sha256-9U1vJyBEvOeesZrttSZg7vMqXSUj4eq/xtB2gRovXiA=";
+  };
+
+  postPatch = ''
+    substituteInPlace tests/by-util/test_setsid.rs \
+      --replace-fail "/usr/bin/cat" "${lib.getExe' coreutils "cat"}" \
+      --replace-fail "/usr/bin/true" "${lib.getExe' coreutils "true"}" \
+      --replace-fail "/usr/bin/false" "${lib.getExe' coreutils "false"}"
+    substituteInPlace tests/by-util/test_setpgid.rs \
+      --replace-fail "echo" "${lib.getExe' coreutils "echo"}" \
+      --replace-fail '"cut"' '"${lib.getExe' coreutils "cut"}"'
+  '';
+
+  cargoHash = "sha256-k1wIiL1DUkk9+UJX+6mgNEW+0zGNHuUTPUk8zuQFo1s=";
+
+  nativeBuildInputs = [
+    pkg-config
+    rustPlatform.bindgenHook
+  ];
+
+  buildInputs = [ util-linux ];
+
+  preBuild = ''
+    export NIX_LDFLAGS="$NIX_LDFLAGS -lsmartcols -lmount"
+  '';
+
+  checkFlags = [
+    # Operation not supported
+    "--skip=common::util::tests::test_compare_xattrs"
+    # can't run on sandbox
+    "--skip=test_last::test_display_hostname_last_column"
+    "--skip=test_last::test_last"
+    "--skip=test_last::test_limit_arg"
+    "--skip=test_last::test_since_only_shows_entries_after_time"
+    "--skip=test_last::test_timestamp_format_full"
+    "--skip=test_last::test_timestamp_format_iso"
+    "--skip=test_last::test_timestamp_format_no_time"
+    "--skip=test_last::test_timestamp_format_short"
+    "--skip=test_last::test_until_only_shows_entries_before_time"
+    "--skip=test_lscpu::test_json"
+    "--skip=test_lscpu::test_output"
+    "--skip=test_lslocks::test_column_headers"
+  ];
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [ "--version=branch" ];
+  };
+
+  meta = {
+    description = "Rust reimplementation of the util-linux project";
+    homepage = "https://github.com/uutils/util-linux";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ kyehn ];
+    platforms = lib.platforms.linux;
+  };
+})